home *** CD-ROM | disk | FTP | other *** search
/ The World's Largest Collection of Windows Software / The World's Largest Collection of Windows Software - Disc 1.iso / connect / _b1 / mrun211 / mrun211.h < prev    next >
Encoding:
Text File  |  1993-05-01  |  92.0 KB  |  3,974 lines
  1. ;MailRun v2.11:  Header File
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This header file contains routines that are used in various
  9. * places throughout the MailRun source files.  It also contains
  10. * global variable definitions and macros.
  11. * 
  12. * #ifdef commands have been used to exclude procedures and global
  13. * variables from being compiled in any script module where they
  14. * are not needed.  In theory, it should not be necessary to do
  15. * this:  Datastorm's documentation says that any procedure or
  16. * variable that isn't used is ignored.  In practice, however, the
  17. * compiler will use up its limited memory resources allocating
  18. * space to variables and procedures that never make their way into
  19. * the compiled script.
  20. * 
  21. * The following procedures/functions are found in this file
  22. * (roughly in order of appearance):
  23. * 
  24. * makefullname(), makemrn(), makebbslist(), maketasklist(), 
  25. * makemailrunlist(), makedesc(), loadsettings(), loadbbsinfo(), 
  26. * loadprompts(), loadmaildoor(), writesettings(), writebbsinfo(), 
  27. * writeprompts(), writemaildoor(), readbbs(), readitem(), 
  28. * writebbs(), writeitem(), getfirstitem(), getlastitem(), 
  29. * gettaskstring(), updatecount(), copymrn(), fverify(), inlist(), 
  30. * openfile(), cleardir(), clearfiledesc(), insertitem(), 
  31. * insertbbs(), changemailrun(), checkpending(), checkchild(), 
  32. * checkrunning(), checkchanged(), checkfile(), checktask(), 
  33. * checknew(), menudim(), sortidx(), fieldcompare(), findstring(), 
  34. * interfaceon(), interfaceoff(), parsedialog(), swapbbs(), 
  35. * swapitem(), changestatus(), taskfilefwd(), taskfileend(), 
  36. * parsemenu(), parseobject(), filenewmrun(), filesave(), filesaveas(), 
  37. * filereset(), filedelmrun(), fileautorun(), fileexit(), editcut(), 
  38. * editcopy(), editpaste(), editdelete(), cfgmrun(), cfgbbs(), 
  39. * cfgprompts(), cfgmaildoor(), configbbs(), configmrun(), 
  40. * configprompts(), configmaildoor(), defaultsmailrun(), defaultsbbs(), 
  41. * defaultsprompts(), defaultsdoor(), addnewbbs(), addgetsend(), 
  42. * addupload(), adddownload(), addsendcmd(), addscript(), 
  43. * executemailrun(), executeqwkreader(), executearchiver(), 
  44. * executelogviewer(), helpcontents(), helpcontext(), helpabout(),
  45. * callscript()
  46. * 
  47. **************************************************************************
  48. **************************************************************************
  49. #endcomment
  50.  
  51. ;Open file indexes
  52.  
  53. #define IniFile 0
  54. #define MailRunFile 1
  55. #define BBSFile 0
  56. #define TaskFile 1
  57. #define OldTaskFile 2
  58. #define TempTaskFile 3
  59. #define BBSidxFile 0
  60. #define BBSdbfFile 1
  61. #define NewFilesFile 2
  62. #define MRUnarcFile 3
  63. #define OldidxFile 4
  64. #define OlddbfFile 5
  65. #define ScriptFile 0
  66. #define QueueListFile 5
  67. #define OldUBFFile 0
  68. #define OldUDXFile 1
  69. #define MRunUBFFile 2
  70. #define MRunUDXFile 3
  71. #define FileDescFile 4
  72. #define SourceFile 5
  73.  
  74. ;Flags
  75.  
  76. #define ALLFLAGS 255                ; 2^8 - 1
  77. #define RUNNING 1                    ; 2^0
  78. #define CHANGED 2                    ; 2^1
  79. #define NEW 4                        ; 2^2
  80. #define AGM 8                        ; 2^3
  81. #define CMD 16                        ; 2^4
  82. #define SCR 32                        ; 2^5
  83. #define ABT 64                        ; 2^6
  84. #define USR 8                        ; 2^3
  85. #define PRMPT 16                    ; 2^4
  86. #define QMD 32                        ; 2^5
  87. #define DEFAULTS 128                ; 2^7
  88. #define IDLE (ALLFLAGS - RUNNING)
  89. #define UNCHANGED (ALLFLAGS - CHANGED)
  90. #define OLD (ALLFLAGS - NEW)
  91. #define CLEARCMD (ALLFLAGS - AGM - CMD - SCR - ABT)
  92.  
  93. ;System global variables
  94.  
  95. #define FLAGS i9
  96. #define IdleTimeout i8
  97. #define LogRun i7
  98. #define AppendLog i6
  99. #define AnsiInLog i5
  100. #define NewfileFilter i4
  101. #define GraphicsOn i3
  102. #define HelpPage i2
  103. #define PostRun i1
  104. #define IdleTimer i0
  105.  
  106. #define TaskItem s9
  107. #define MailRun s8
  108. #define MailRunIni s7
  109. #define TempDir s6
  110. #define MailRunDir s5
  111. #define TaskList s4
  112. #define BBS s3
  113. #define Item s2
  114. #define Conf s1
  115. #define CurrentConf s0
  116.  
  117. ;Macros
  118.  
  119. #define EscapeFail 0
  120. #define ErrorFail 1
  121. #define ALPHA 0
  122. #define NUMERIC 1
  123. #define MMDDYY 2
  124. #define _READWRITE 0
  125. #define _CREATE 1
  126. #define _TEXT 0
  127. #define _NORMAL 1
  128.  
  129. ;Miscellaneous global variables
  130.  
  131. string     MailRunTrunc
  132.  
  133. #ifndef MRUN211G
  134. #ifndef MRUN211B
  135. string    BBSList
  136. #endif
  137. #ifndef MRUN211F
  138. string    BBSType
  139. #endif
  140. #ifndef MRUN211AB
  141. #ifndef MRUN211C
  142. integer PermRadio
  143. #endif
  144. #endif
  145. #endif
  146.  
  147. #ifdef MRUN211AB
  148. string MailRunList
  149. #endif
  150.  
  151. #ifdef MRUN211DE
  152. string     FileName,        FileDesc,        FileChoice
  153. #endif
  154.  
  155. ;Global variables containing values displayed in the main dialogbox
  156.  
  157. #ifdef MRUN211AG
  158. string     BBSTotal,         BBSComplete,     BBSRemaining,    AttemptNum
  159. string     ItemTotal,         ItemComplete,    ItemError,         ItemRemaining
  160. integer     BBST, BBSC, BBSR, ItemT, ItemC, ItemE, ItemR
  161. #endif
  162.  
  163.  
  164. ;Global variables containing values from [MailRun] section of *.MRN
  165.  
  166. #ifdef MRUN211AB
  167. string     MailDir,            ReplyDir,        DownloadDir,    UploadDir
  168. string    DialAttempts,    DialTimeout,    DialPause
  169. string    SavePackets,    IdleTime,        ExecTime
  170. string    Archiver,        QWKReader,        LogViewer
  171. integer  GoWait
  172. #endif
  173.  
  174.  
  175. #ifndef MRUN211DE
  176. #ifndef MRUN211F
  177. #ifndef MRUN211G
  178.  
  179. ;Global variables containing general BBS info from *.MRN
  180.  
  181. string    BBSName,            UserName,        PWord,        XferProt
  182. string    CallingFrom,    UserResp1,        UserResp2
  183. string     Number_1,        Number_2,        Number_3
  184. string    LangNumber,        MailDoorType
  185.  
  186. ;Global variables containing BBS prompts from MAILRUN.INI
  187.  
  188. string     LangPrompt,        GraphicsPrompt,    NamePrompt,            UserPrompt1
  189. string    PWordPrompt,    ViewPrompt,            FilePrompt,            UserPrompt2
  190. string    ScanPrompt,        MorePrompt,            ContinuePrompt,    CommandPrompt
  191. string    DLPrompt,        DLUnavPrompt,        ULPrompt,            ULDescPrompt
  192.  
  193. ;Global variables containing Mail Door prompts from MAILRUN.INI
  194.  
  195. string    MailPrompt,        ReceiveQWKPrompt,    MailDLPrompt,  MsgMenuPrompt
  196. string     MailXferProt,    MailULPrompt,         QWKArchiver,    MailDoor
  197.  
  198. #endif
  199. #endif
  200. #endif
  201.  
  202.  
  203. #comment
  204. *********************************************************************
  205. * 
  206. * MAKEFULLNAME()
  207. * 
  208. * Called by all modules, various procedures
  209. * 
  210. * Appends a filename to a directory name.
  211. * 
  212. *********************************************************************
  213. #endcomment
  214.  
  215. func makefullname : string
  216. strparm Directory, FileNamen
  217. string FullName
  218.     FullName = Directory
  219.     addfilename FullName FileNamen
  220.     return FullName
  221. endfunc
  222.  
  223.  
  224. #comment
  225. *********************************************************************
  226. * 
  227. * MAKEMRN()
  228. * 
  229. * Calls loadsettings(), loadbbsinfo(), loadprompts(), loadmaildoor(),
  230. * writesettings(), writebbsinfo(), writeprompts(), writemaildoor(),
  231. * makefullname(), filesave()
  232. * 
  233. * Called by:
  234. *     MRUN211A:  initialize()
  235. *     MRUN211B:  newmailrun()
  236. * 
  237. * Create the file MAILRUN.MRN and initialize it.
  238. * 
  239. *********************************************************************
  240. #endcomment
  241.  
  242. #ifdef MRUN211AB
  243. proc makemrn
  244. string DLPurgeLimit
  245. #ifndef MRUN211A
  246. string RingInterrupt
  247. #endif
  248.     ;load the defaults 
  249.     loadsettings(MailRunIni)
  250.     loadbbsinfo(MailRunIni, "DEFAULT")
  251.     loadprompts(MailRunIni, "DEFAULT")
  252.     loadmaildoor(MailRunIni, "DEFAULT")
  253.     profilerd MailRunIni "MailRun" "DLPurgeLimit" DLPurgeLimit
  254.     profilerd MailRunIni "MailRun" "ExecTime" ExecTime
  255.     profilerd MailRunIni "MailRun" "GoWait" GoWait
  256.     profilerd MailRunIni "MailRun" "PostRun" PostRun
  257.     profilerd MailRunIni "MailRun" "RingInterrupt" RingInterrupt
  258.     ;write the defaults to the new mailrun
  259.     MailRun = makefullname(TempDir, MailRunTrunc)
  260.     writesettings(MailRun)
  261.     writebbsinfo(MailRun, "DEFAULT")
  262.     writeprompts(MailRun, "DEFAULT")
  263.     writemaildoor(MailRun, "DEFAULT")
  264.     profilewr MailRun "MailRun" "DLPurgeLimit" DLPurgeLimit
  265.     profilewr MailRun "MailRun" "ExecTime" ExecTime
  266.     profilewr MailRun "MailRun" "GoWait" GoWait
  267.     profilewr MailRun "MailRun" "PostRun" PostRun
  268.     profilewr MailRun "MailRun" "RingInterrupt" RingInterrupt
  269.     ;write the new mailrun to disk
  270.     filesave()
  271. endproc
  272. #endif
  273.  
  274.  
  275. #comment
  276. *********************************************************************
  277. * 
  278. * MAKEBBSLIST()
  279. * 
  280. * Calls readbbs()
  281. * 
  282. * Called by:
  283. *     MRUN211H:  editdelete(), editpaste(), callscript()
  284. *     MRUN211C:  changeuserinfo(), changeprompts(), changemaildoor()
  285. *     MRUN211D:  main()
  286. *     MRUN211E:  main()
  287. *     MRUN211F:  addgetmail(), addsendcommand(), adddoscript()
  288. * 
  289. * Creates a list of BBSs for display the BBS combobox of
  290. * various dialog boxes.
  291. * 
  292. *********************************************************************
  293. #endcomment
  294.  
  295. #ifndef MRUN211G
  296. #ifndef MRUN211B
  297. proc makebbslist
  298. string BBSid
  299. integer i
  300.     BBSList = ""
  301.     i = 1
  302.     BBSid = readbbs(i)
  303.     while not NULLSTR BBSid
  304.         strlwr BBSid
  305.         strfmt BBSList "%s,%s" BBSList BBSid
  306.         i++
  307.         BBSid = readbbs(i)
  308.     endwhile
  309.     if i > 1
  310.         strdelete BBSList 0 1
  311.     endif
  312. endproc
  313. #endif
  314. #endif
  315.  
  316.  
  317. #comment
  318. *********************************************************************
  319. * 
  320. * MAKETASKLIST()
  321. * 
  322. * Calls openfile(), gettaskstring(), readbbs(), readitem(),
  323. * makefullname(), updatecount()
  324. * 
  325. * Called by:
  326. *     MRUN211H:  parsedialog(), changestatus(), filereset(),
  327. *                   filedelmrun(), editpaste(), editdelete(),
  328. *             callscript()
  329. *     MRUN211A:  main(), executor()
  330. *     MRUN211G:  main(), dobbs()
  331. * 
  332. * 
  333. * Creates the Task List displayed in the main MailRun
  334. * dialog box.  Each item of each BBS is read from the *.MRN
  335. * file and a "TaskString" is produced to describe its contents.
  336. * The BBS and Item coordinates are appended to the TaskString
  337. * as an index back into the *.MRN file.  Tabstops are used to
  338. * push these indexes beyond the right edge of the Task List
  339. * flistbox so that they are not visible.  TaskStrings for BBS
  340. * names have an item coordinate of zero.
  341. * 
  342. * Also calculates the values of variables displayed in the
  343. * statistics section of the main dialog box.
  344. * 
  345. *********************************************************************
  346. #endcomment
  347.  
  348. #ifdef MRUN211AG
  349. proc maketasklist
  350. string TaskString, Tasks, Pending
  351. string BBSid, Itemj
  352. integer i, j
  353.     ;set all values displayed in main dialog box to 0
  354.     BBST = 0
  355.     BBSC = 0
  356.     BBSR = 0
  357.     ItemT = 0
  358.     ItemC = 0
  359.     ItemE = 0
  360.     Tasks = makefullname(TempDir, "TASKLIST.TMP")
  361.     ;Save the values for the current BBS and Item
  362.     openfile(TaskFile, Tasks, _CREATE, _TEXT)
  363.     i = 1
  364.     BBSid = readbbs(i)
  365.     while not NULLSTR BBSid
  366.         ;Loop through each BBS in the MailRun
  367.         ItemR = 0
  368.         j = 0
  369.         TaskString = gettaskstring(BBSid, 0)
  370.         fputs TaskFile TaskString
  371.         j++
  372.         Itemj = readitem(BBSid, j)
  373.         while not NULLSTR Itemj
  374.             ;Loop through each Item
  375.             strextract Pending Itemj "," 0
  376.             if strcmpi Pending "0"
  377.                 ItemC++
  378.             elseif strcmpi Pending "1"
  379.                 ItemR++
  380.             else
  381.                 ItemE++
  382.             endif
  383.             TaskString = gettaskstring(BBSid, j)
  384.             fputs TaskFile TaskString
  385.             ItemT++
  386.             j++
  387.             Itemj = readitem(BBSid, j)
  388.         endwhile
  389.         BBST++
  390.         if ItemR == 0
  391.             BBSC++
  392.         endif
  393.         i++
  394.         BBSid = readbbs(i)
  395.     endwhile
  396.     fclose TaskFile
  397.     ;prepare statistics variables for display in the main box
  398.     BBSR = BBST - BBSC
  399.     ItemR = ItemT - ItemC - ItemE
  400.     updatecount()
  401. endproc
  402. #endif
  403.  
  404.  
  405. #comment
  406. *********************************************************************
  407. * 
  408. * MAKEMAILRUNLIST()
  409. * 
  410. * Calls makefullname()
  411. * 
  412. * Called by:
  413. *     MRUN211H:  filesaveas(), filedelmrun(), callscript()
  414. *     MRUN211A:  main()
  415. *     MRUN211B:  main(), newmailrun()
  416. * 
  417. * Creates a list of MailRuns for display in the main
  418. * MailRun and MailRun Settings dialog boxes.
  419. * 
  420. *********************************************************************
  421. #endcomment
  422.  
  423. #ifdef MRUN211AB
  424. proc makemailrunlist
  425. string FileTrunc, MRNFile
  426.     MailRunList = ""
  427.     MRNFile = makefullname(MailRunDir, "*.MRN")
  428.     findfirst MRNFile
  429.     ;Loop through all files in the directory
  430.     while FOUND
  431.         FileTrunc = $FILENAME
  432.         strlwr FileTrunc
  433.         strfmt MailRunList "%s,%s" MailRunList FileTrunc
  434.         findnext
  435.     endwhile
  436.     if not NULLSTR MailRunList
  437.         strdelete MailRunList 0 1
  438.     endif
  439. endproc
  440. #endif
  441.  
  442.  
  443. #comment
  444. *********************************************************************
  445. * 
  446. * MAKEDESC()
  447. * 
  448. * Calls openfile()
  449. * 
  450. * Called by:
  451. *     MRUN211D:  main(), deldlfile()
  452. *     MRUN211E:  getnewdesc()
  453. * 
  454. * Creates the file description for display in the upload
  455. * and download dialog boxes.
  456. * 
  457. *********************************************************************
  458. #endcomment
  459.  
  460. #ifdef MRUN211DE
  461. proc makedesc
  462. strparm DescSource
  463. string DB, DL
  464. integer char
  465. long DescBegin, DescLength, counter
  466.     strextract DB FileChoice "`t" 4
  467.     atol DB DescBegin
  468.     strextract DL FileChoice "`t" 5
  469.     atol DL DescLength
  470.     if DescLength != 0
  471.         ;if there is a description in the database, retrieve it
  472.         openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  473.         openfile(SourceFile, DescSource, _READWRITE, _NORMAL)
  474.         fseek SourceFile DescBegin 0
  475.         for counter = 1 upto DescLength
  476.             fgetc SourceFile char
  477.             fputc FileDescFile char
  478.         endfor
  479.         fclose FileDescFile
  480.         fclose SourceFile
  481.     else
  482.         ;otherwise, just delete the previous description
  483.         openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  484.         fclose FileDescFile
  485.     endif
  486. endproc
  487. #endif
  488.  
  489.  
  490. #comment
  491. *********************************************************************
  492. * 
  493. * LOADSETTINGS()
  494. * 
  495. * Called by:
  496. *     MRUN211H:  makemrn(), changemailrun()
  497. *     MRUN211B:  main()
  498. * 
  499. * Initializes MailRun settings.
  500. * 
  501. *********************************************************************
  502. #endcomment
  503.  
  504. #ifdef MRUN211AB
  505. proc loadsettings
  506. strparm _MailRun
  507.     profilerd _MailRun "MailRun" "MailDir" MailDir
  508.     profilerd _MailRun "MailRun" "ReplyDir" ReplyDir
  509.     profilerd _MailRun "MailRun" "DownloadDir" DownloadDir
  510.     profilerd _MailRun "MailRun" "UploadDir" UploadDir
  511.     profilerd _MailRun "MailRun" "SavePackets" SavePackets
  512.     profilerd _MailRun "MailRun" "DialAttempts" DialAttempts
  513.     profilerd _MailRun "MailRun" "DialTimeout" DialTimeout
  514.     profilerd _MailRun "MailRun" "DialPause" DialPause
  515.     profilerd _MailRun "MailRun" "IdleTimeout" IdleTime
  516.     profilerd _MailRun "MailRun" "LogRun" LogRun
  517.     profilerd _MailRun "MailRun" "AppendLog" AppendLog
  518.     profilerd _MailRun "MailRun" "AnsiInLog" AnsiInLog
  519.     profilerd _MailRun "MailRun" "NewfileFilter" NewfileFilter
  520.     profilerd _MailRun "MailRun" "Archiver" Archiver
  521.     profilerd _MailRun "MailRun" "QWKReader" QWKReader
  522.     profilerd _MailRun "MailRun" "LogViewer" LogViewer
  523. endproc
  524. #endif
  525.  
  526.  
  527. #comment
  528. *********************************************************************
  529. * 
  530. * WRITESETTINGS()
  531. * 
  532. * Called by:  
  533. *     MRUN211H:  makemrn()
  534. *     MRUN211B:  main()
  535. * 
  536. * Writes MailRun settings to the *.MRN file.
  537. * 
  538. *********************************************************************
  539. #endcomment
  540.  
  541. #ifdef MRUN211AB
  542. proc writesettings
  543. strparm _MailRun
  544.     profilewr _MailRun "MailRun" "MailDir" MailDir
  545.     profilewr _MailRun "MailRun" "ReplyDir" ReplyDir
  546.     profilewr _MailRun "MailRun" "DownloadDir" DownloadDir
  547.     profilewr _MailRun "MailRun" "UploadDir" UploadDir
  548.     profilewr _MailRun "MailRun" "DialAttempts" DialAttempts
  549.     profilewr _MailRun "MailRun" "DialTimeout" DialTimeout
  550.     profilewr _MailRun "MailRun" "DialPause" DialPause
  551.     profilewr _MailRun "MailRun" "IdleTimeout" IdleTime
  552.     profilewr _MailRun "MailRun" "SavePackets" SavePackets
  553.     profilewr _MailRun "MailRun" "LogRun" LogRun
  554.     profilewr _MailRun "MailRun" "AppendLog" AppendLog
  555.     profilewr _MailRun "MailRun" "AnsiInLog" AnsiInLog
  556.     profilewr _MailRun "MailRun" "NewfileFilter" NewfileFilter
  557.     profilewr _MailRun "MailRun" "Archiver" Archiver
  558.     profilewr _MailRun "MailRun" "QWKReader" QWKReader
  559.     profilewr _MailRun "MailRun" "LogViewer" LogViewer
  560. endproc
  561. #endif
  562.  
  563.  
  564. #comment
  565. *********************************************************************
  566. * 
  567. * LOADBBSINFO()
  568. * 
  569. * Called by:
  570. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  571. *     MRUN211C:  changeuserinfo(), addbbs()
  572. * 
  573. * Initializes BBS information.
  574. * 
  575. *********************************************************************
  576. #endcomment
  577.  
  578. #ifndef MRUN211DE
  579. #ifndef MRUN211F
  580. #ifndef MRUN211G
  581. proc loadbbsinfo
  582. strparm _MailRun, _BBS
  583.     profilerd _MailRun _BBS "BBSName" BBSName
  584.     profilerd _MailRun _BBS "UserName" UserName
  585.     profilerd _MailRun _BBS "PWord" Pword
  586.     profilerd _MailRun _BBS "XferProt" XferProt
  587.     profilerd _MailRun _BBS "MailXferProt" MailXferProt
  588.     profilerd _MailRun _BBS "QWKArchiver" QWKArchiver
  589.     profilerd _MailRun _BBS "Number_1" Number_1
  590.     profilerd _MailRun _BBS "Number_2" Number_2
  591.     profilerd _MailRun _BBS "Number_3" Number_3
  592.     profilerd _MailRun _BBS "BBSType" BBSType
  593.     profilerd _MailRun _BBS "MailDoorType" MailDoorType
  594. endproc
  595. #endif
  596. #endif
  597. #endif
  598.  
  599.  
  600. #comment
  601. *********************************************************************
  602. * 
  603. * WRITEBBSINFO()
  604. * 
  605. * Called by:
  606. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  607. *     MRUN211C:  changeuserinfo()
  608. * 
  609. * Writes information for current BBS to the *.MRN file.
  610. * 
  611. *********************************************************************
  612. #endcomment
  613.  
  614. #ifndef MRUN211DE
  615. #ifndef MRUN211F
  616. #ifndef MRUN211G
  617. proc writebbsinfo
  618. strparm _MailRun, _BBS
  619.     profilewr _MailRun _BBS "BBSName" BBSName
  620.     profilewr _MailRun _BBS "UserName" UserName
  621.     profilewr _MailRun _BBS "PWord" PWord
  622.     profilewr _MailRun _BBS "XferProt" XferProt
  623.     profilewr _MailRun _BBS "MailXferProt" MailXferProt
  624.     profilewr _MailRun _BBS "QWKArchiver" QWKArchiver
  625.     profilewr _MailRun _BBS "Number_1" Number_1
  626.     profilewr _MailRun _BBS "Number_2" Number_2
  627.     profilewr _MailRun _BBS "Number_3" Number_3
  628.     profilewr _MailRun _BBS "BBSType" BBSType
  629.     profilewr _MailRun _BBS "MailDoorType" MailDoorType
  630. endproc
  631. #endif
  632. #endif
  633. #endif
  634.  
  635.  
  636. #comment
  637. *********************************************************************
  638. * 
  639. * LOADPROMPTS()
  640. * 
  641. * Called by:
  642. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  643. *     MRUN211C:  changeuserinfo(), changeprompts(), addbbs()
  644. * 
  645. * Initializes BBS prompts.
  646. * 
  647. *********************************************************************
  648. #endcomment
  649.  
  650. #ifndef MRUN211DE
  651. #ifndef MRUN211F
  652. #ifndef MRUN211G
  653. proc loadprompts
  654. strparm _MailRun, _BBS
  655.     profilerd _MailRun _BBS "CallingFrom" CallingFrom
  656.     profilerd _MailRun _BBS "UserResp1" UserResp1
  657.     profilerd _MailRun _BBS "UserResp2" UserResp2
  658.     profilerd _MailRun _BBS "LangNumber" LangNumber
  659.     profilerd _MailRun _BBS "GraphicsOn" GraphicsOn
  660.     profilerd _MailRun _BBS "LangPrompt" LangPrompt
  661.     profilerd _MailRun _BBS "GraphicsPrompt" GraphicsPrompt
  662.     profilerd _MailRun _BBS "NamePrompt" NamePrompt
  663.     profilerd _MailRun _BBS "PWordPrompt" PWordPrompt
  664.     profilerd _MailRun _BBS "UserPrompt1" UserPrompt1
  665.     profilerd _MailRun _BBS "UserPrompt2" UserPrompt2
  666.     profilerd _MailRun _BBS "ViewPrompt" ViewPrompt
  667.     profilerd _MailRun _BBS "ScanPrompt" ScanPrompt
  668.     profilerd _MailRun _BBS "FilePrompt" FilePrompt
  669.     profilerd _MailRun _BBS "MorePrompt" MorePrompt
  670.     profilerd _MailRun _BBS "ContinuePrompt" ContinuePrompt
  671.     profilerd _MailRun _BBS "CommandPrompt" CommandPrompt
  672.     profilerd _MailRun _BBS "DLPrompt" DLPrompt
  673.     profilerd _MailRun _BBS "DLUnavPrompt" DLUnavPrompt
  674.     profilerd _MailRun _BBS "ULPrompt" ULPrompt
  675.     profilerd _MailRun _BBS "ULDescPrompt" ULDescPrompt
  676. endproc
  677. #endif
  678. #endif
  679. #endif
  680.  
  681.  
  682. #comment
  683. *********************************************************************
  684. * 
  685. * WRITEPROMPTS()
  686. * 
  687. * Called by:
  688. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  689. *     MRUN211C:  changeuserinfo(), changeprompts(), exportprompts()
  690. * 
  691. * Writes prompts for current BBS to the *.MRN file.
  692. * 
  693. *********************************************************************
  694. #endcomment
  695.  
  696. #ifndef MRUN211DE
  697. #ifndef MRUN211F
  698. #ifndef MRUN211G
  699. proc writeprompts
  700. strparm _MailRun, _BBS
  701.     profilewr _MailRun _BBS "CallingFrom" CallingFrom
  702.     profilewr _MailRun _BBS "UserResp1" UserResp1
  703.     profilewr _MailRun _BBS "UserResp2" UserResp2
  704.     profilewr _MailRun _BBS "LangNumber" LangNumber
  705.     profilewr _MailRun _BBS "GraphicsOn" GraphicsOn
  706.     profilewr _MailRun _BBS "LangPrompt" LangPrompt
  707.     profilewr _MailRun _BBS "GraphicsPrompt" GraphicsPrompt
  708.     profilewr _MailRun _BBS "NamePrompt" NamePrompt
  709.     profilewr _MailRun _BBS "PWordPrompt" PWordPrompt
  710.     profilewr _MailRun _BBS "UserPrompt1" UserPrompt1
  711.     profilewr _MailRun _BBS "UserPrompt2" UserPrompt2
  712.     profilewr _MailRun _BBS "ViewPrompt" ViewPrompt
  713.     profilewr _MailRun _BBS "ScanPrompt" ScanPrompt
  714.     profilewr _MailRun _BBS "FilePrompt" FilePrompt
  715.     profilewr _MailRun _BBS "MorePrompt" MorePrompt
  716.     profilewr _MailRun _BBS "ContinuePrompt" ContinuePrompt
  717.     profilewr _MailRun _BBS "CommandPrompt" CommandPrompt
  718.     profilewr _MailRun _BBS "DLPrompt" DLPrompt
  719.     profilewr _MailRun _BBS "DLUnavPrompt" DLUnavPrompt
  720.     profilewr _MailRun _BBS "ULPrompt" ULPrompt
  721.     profilewr _MailRun _BBS "ULDescPrompt" ULDescPrompt
  722. endproc
  723. #endif
  724. #endif
  725. #endif
  726.  
  727.  
  728. #comment
  729. *********************************************************************
  730. * 
  731. * LOADMAILDOOR()
  732. * 
  733. * Called by:
  734. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  735. *     MRUN211C:  changeuserinfo(), changemaildoor(), addbbs()
  736. * 
  737. * Initializes mail door prompts.
  738. * 
  739. *********************************************************************
  740. #endcomment
  741.  
  742. #ifndef MRUN211DE
  743. #ifndef MRUN211F
  744. #ifndef MRUN211G
  745. proc loadmaildoor
  746. strparm _MailRun, _BBS
  747.     profilerd _MailRun _BBS "MailDoor" MailDoor
  748.     profilerd _MailRun _BBS "MailPrompt" MailPrompt
  749.     profilerd _MailRun _BBS "ReceiveQWKPrompt" ReceiveQWKPrompt
  750.     profilerd _MailRun _BBS "MailDLPrompt" MailDLPrompt
  751.     profilerd _MailRun _BBS "MailULPrompt" MailULPrompt
  752.     profilerd _MailRun _BBS "MsgMenuPrompt" MsgMenuPrompt
  753. endproc
  754. #endif
  755. #endif
  756. #endif
  757.  
  758.  
  759. #comment
  760. *********************************************************************
  761. * 
  762. * WRITEMAILDOOR()
  763. * 
  764. * Called by:
  765. *     MRUN211H:  makemrn(), editcopy(), editpaste()
  766. *     MRUN211C:  changeuserinfo(), changemaildoor(), 
  767. *                   exportmaildoor()
  768. * 
  769. * Writes mail door prompts for the current BBS to the .MRN
  770. * file.
  771. * 
  772. *********************************************************************
  773. #endcomment
  774.  
  775. #ifndef MRUN211DE
  776. #ifndef MRUN211F
  777. #ifndef MRUN211G
  778. proc writemaildoor
  779. strparm _MailRun, _BBS
  780.     profilewr _MailRun _BBS "MailDoor" MailDoor
  781.     profilewr _MailRun _BBS "MailPrompt" MailPrompt
  782.     profilewr _MailRun _BBS "ReceiveQWKPrompt" ReceiveQWKPrompt
  783.     profilewr _MailRun _BBS "MailDLPrompt" MailDLPrompt
  784.     profilewr _MailRun _BBS "MailULPrompt" MailULPrompt
  785.     profilewr _MailRun _BBS "MsgMenuPrompt" MsgMenuPrompt
  786. endproc
  787. #endif
  788. #endif
  789. #endif
  790.  
  791.  
  792. #comment
  793. *********************************************************************
  794. * 
  795. * READBBS()
  796. * 
  797. * Called by:
  798. *     MRUN211H:  makebbslist(), maketasklist(), getbbscoord(), 
  799. *                   insertbbs(), swapbbs(), filereset(), editdelete()
  800. *     MRUN211G:  main(), makequeue()
  801. * 
  802. * Reads the BBS associated with a BBS coordinate in the
  803. * current mailrun.
  804. * 
  805. *********************************************************************
  806. #endcomment
  807.  
  808. func readbbs : string
  809. intparm i
  810. string BBS_X, BBSid
  811.     strfmt BBS_X "BBS_%d" i
  812.     profilerd MailRun "MailRun" BBS_X BBSid
  813.     return BBSid
  814. endfunc
  815.  
  816.  
  817. #comment
  818. *********************************************************************
  819. * 
  820. * READITEM()
  821. * 
  822. * Called by:
  823. *     MRUN211H:  maketasklist(), getlastitem(), insertitem(), 
  824. *                   checkpending(), swapitem(), filereset(), 
  825. *                   changestatus(), editcopy(), editdelete()
  826. *     MRUN211G:  dobbs()
  827. * 
  828. * Reads the Item associated with a BBS coordinate in the
  829. * current mailrun.
  830. * 
  831. *********************************************************************
  832. #endcomment
  833.  
  834. func readitem : string
  835. strparm BBSid
  836. intparm i
  837. string Item_X, Itemi
  838.     strfmt Item_X "Item_%d" i
  839.     profilerd MailRun BBSid Item_X Itemi
  840.     return Itemi
  841. endfunc
  842.  
  843.  
  844. #comment
  845. *********************************************************************
  846. * 
  847. * WRITEBBS()
  848. * 
  849. * Called by:
  850. *     MRUN211H:  insertbbs(), swapbbs(), editdelete()
  851. *     MRUN211C:  changeusersettings()
  852. * 
  853. * Writes a BBS ID to the given coordinate in the current
  854. * mailrun.
  855. * 
  856. *********************************************************************
  857. #endcomment
  858.  
  859. proc writebbs
  860. intparm i
  861. strparm BBSid
  862. string BBS_X
  863.     strfmt BBS_X "BBS_%d" i
  864.     profilewr MailRun "MailRun" BBS_X BBSid
  865. endproc
  866.  
  867.  
  868. #comment
  869. *********************************************************************
  870. * 
  871. * WRITEITEM()
  872. * 
  873. * Called by:
  874. *     MRUN211H:  swapitem(), insertitem(), editdelete(), filereset(),
  875. *                   changestatus()
  876. *     MRUN211G:  dobbs()
  877. * 
  878. * Writes an Item to the given Item coordinate for the
  879. * current BBS and MailRun.
  880. * 
  881. *********************************************************************
  882. #endcomment
  883.  
  884. proc writeitem
  885. strparm BBSid
  886. intparm i
  887. strparm Itemi
  888. string Item_X
  889.     strfmt Item_X "Item_%d" i
  890.     profilewr MailRun BBSid Item_X Itemi
  891. endproc
  892.  
  893.  
  894. #comment
  895. *********************************************************************
  896. * 
  897. * GETBBSCOORD()
  898. * 
  899. * Calls readbbs()
  900. * 
  901. * Called by:
  902. *     MRUN210H:  parsedialog(), editdelete()
  903. * 
  904. * Gets the BBS coordinate for a given BBS ID.
  905. * 
  906. *********************************************************************
  907. #endcomment
  908.  
  909. #ifdef MRUN211AG
  910. func getbbscoord : integer
  911. strparm BBSid
  912. integer i
  913. string BBSi
  914.     i = 1
  915.     BBSi = readbbs(i)
  916.     while not strcmpi BBSid BBSi
  917.         i++
  918.         BBSi = readbbs(i)
  919.     endwhile
  920.     return i
  921. endfunc
  922. #endif
  923.  
  924.  
  925. #comment
  926. *********************************************************************
  927. * 
  928. * GETFIRSTITEM()
  929. *
  930. * Calls gettaskstring()
  931. * 
  932. * Called by:
  933. *     MRUN211H:  parsedialog(), filereset(), filedelmrun(),
  934. *             callscript()
  935. *     MRUN211A:  main()
  936. *  MRUN211B:  main()
  937. * 
  938. * Highlights the first item in the task list.
  939. * 
  940. *********************************************************************
  941. #endcomment
  942.  
  943. proc getfirstitem
  944. string BBSid
  945.     profilerd MailRun "MailRun" "BBS_1" BBSid
  946.     if not NULLSTR BBSid
  947.         TaskItem = gettaskstring(BBSid, 0)
  948.     else
  949.         TaskItem = ""
  950.     endif
  951. endproc
  952.  
  953.  
  954. #comment
  955. *********************************************************************
  956. * 
  957. * GETLASTITEM()
  958. * 
  959. * Calls readitem()
  960. * 
  961. * Called by:
  962. *     MRUN211D:  main()
  963. *     MRUN211E:  main()
  964. *     MRUN211F:  addgetmail(), addsendcommand(), adddoscript()
  965. * 
  966. * Gets the Item coordinate for a given Item in the current
  967. * BBS.
  968. * 
  969. *********************************************************************
  970. #endcomment
  971.  
  972. func getlastitem : integer
  973. strparm BBSid
  974. string Itemi
  975. integer i
  976.     i = 1
  977.     Itemi = readitem(BBSid, i)
  978.     while not NULLSTR Itemi
  979.         i++
  980.         Itemi = readitem(BBSid, i)
  981.     endwhile
  982.     i--
  983.     return i
  984. endfunc
  985.  
  986.  
  987. #comment
  988. *********************************************************************
  989. * 
  990. * GETTASKSTRING()
  991. * 
  992. * Called by:
  993. *     MRUN211H:  maketasklist(), parsedialog(), swapbbs(), swapitem(), 
  994. *             editdelete(), changestatus(), editpaste()
  995. *     MRUN211C:  changeuserinfo(), changeprompts(), changemaildoor()
  996. *     MRUN211D:  main()
  997. *     MRUN211E:  main()
  998. *     MRUN211F:  addgetmail(), addsendmail(), adddoscript()
  999. *     MRUN211G:  dobbs()
  1000. * 
  1001. * Produces a TaskString from the current *.MRN Item.
  1002. * Items are strings with the format:
  1003. * 
  1004. *         "Pending,Perm,TaskType,FileName,Conf"
  1005. * 
  1006. * Pending = 0 if item is completed, 1 if pending, 2 if an
  1007. *         error occurred in previous attempt to execute it.
  1008. * Perm = 1 if the item is permanent; Perm = 2 if temporary.
  1009. * TaskType may be SendMail, GetMail, SendFile, GetFile,
  1010. *         SendCommand or SendScript.
  1011. * FileName is the name of the file to be transferred, used
  1012. *         by SendFile and GetFile items.
  1013. * Conf is the number of the conference to be joined, used
  1014. *         by SendFile and GetFile items.
  1015. * 
  1016. *********************************************************************
  1017. #endcomment
  1018.  
  1019. func gettaskstring : string
  1020. strparm BBSid
  1021. intparm j
  1022. string Pending, Perm, TaskType, TaskString, KeyString, BBSNamen
  1023. string char, Item_X, Itemi, Confi
  1024.     if j == 0
  1025.         ;if this is for a BBS name
  1026.         profilerd MailRun BBSid "BBSName" BBSNamen
  1027.         strfmt TaskString "%s`t`t`t%s`t%d" BBSNamen BBSid j
  1028.     else
  1029.         ;if this is for an item
  1030.         strfmt Item_X "Item_%d" j
  1031.         profilerd MailRun BBSid Item_X Itemi
  1032.         strextract Pending Itemi "," 0
  1033.         strextract Perm Itemi "," 1
  1034.         strextract TaskType Itemi "," 2
  1035.         if strcmpi Pending "1"
  1036.             If strcmpi Perm "1"
  1037.                 char = "#"
  1038.             else
  1039.                 char = "ñ"
  1040.             endif
  1041.         elseif strcmpi Pending "0"
  1042.             char = "@"
  1043.         else
  1044.             char = " !"
  1045.         endif
  1046.         switch TaskType
  1047.             case "SendMail"
  1048.                 TaskString = "Send REP Packet"
  1049.             endcase
  1050.             case "GetMail"
  1051.                 TaskString = "Get QWK Packet"
  1052.             endcase
  1053.             case "SendFile"
  1054.                 strextract KeyString Itemi "," 3
  1055.                 strextract Confi Itemi "," 4
  1056.                 strfmt TaskString "Upload %s to File Area %s" KeyString Confi
  1057.             endcase
  1058.             case "GetFile"
  1059.                 strextract keystring Itemi "," 3
  1060.                 strextract Confi Itemi "," 4
  1061.                 strfmt TaskString "Download %s from File Area %s" KeyString Confi
  1062.             endcase
  1063.             case "SendCommand"
  1064.                 strextract KeyString Itemi "," 3
  1065.                 strfmt TaskString "Send Command:  %s" KeyString
  1066.             endcase
  1067.             case "SendScript"
  1068.                 strextract KeyString Itemi "," 3
  1069.                 strfmt TaskString "Execute Script:  %s" KeyString
  1070.             endcase
  1071.         endswitch
  1072.         strfmt TaskString "`t%s`t%s`t%s`t%d" char TaskString BBSid j
  1073.     endif
  1074.     return TaskString
  1075. endfunc
  1076.  
  1077.  
  1078. #comment
  1079. *********************************************************************
  1080. * 
  1081. * UPDATECOUNT()
  1082. * 
  1083. * Called by:
  1084. *     MRUN211H:  maketasklist(), changestatus()
  1085. *     MRUN211G:  dobbs()
  1086. * 
  1087. * Updates the statistics section of the main MailRun dialog box.
  1088. * 
  1089. *********************************************************************
  1090. #endcomment
  1091.  
  1092. #ifdef MRUN211AG
  1093. proc updatecount
  1094.     itoa BBST BBSTotal
  1095.     itoa BBSC BBSComplete
  1096.     itoa BBSR BBSRemaining
  1097.     itoa ItemT ItemTotal
  1098.     itoa ItemC ItemComplete
  1099.     itoa ItemE ItemError
  1100.     itoa ItemR ItemRemaining
  1101. endproc
  1102. #endif
  1103.  
  1104.  
  1105. #comment
  1106. *********************************************************************
  1107. * 
  1108. * COPYMRN()
  1109. * 
  1110. * Calls makefullname()
  1111. * 
  1112. * Called by:
  1113. *     MRUN211H:  changemailrun(), filesaveas(), filedelmrun()
  1114. * 
  1115. * Copies a mailrun from MailRunDir to TempDir.
  1116. * 
  1117. *********************************************************************
  1118. #endcomment
  1119.  
  1120. #ifdef MRUN211AB
  1121. proc copymrn
  1122. string LastRun
  1123.     delfile MailRun
  1124.     LastRun = makefullname(MailRunDir, MailRunTrunc)
  1125.     MailRun = makefullname(TempDir, MailRunTrunc)
  1126.     copyfile LastRun MailRun
  1127. endproc
  1128. #endif
  1129.  
  1130.  
  1131. #comment
  1132. *********************************************************************
  1133. * 
  1134. * FVERIFY()
  1135. * 
  1136. * Called by:
  1137. *     MRUN211H:  filesaveas()
  1138. *     MRUN211B:  newmailrun()
  1139. *     MRUN211C:  addbbs()
  1140. * 
  1141. * Checks for a valid DOS filename (sans extension).
  1142. * Returns 1 if valid, 0 if invalid.
  1143. * 
  1144. *********************************************************************
  1145. #endcomment
  1146.  
  1147. #ifndef MRUN211DE
  1148. #ifndef MRUN211F
  1149. #ifndef MRUN211G
  1150. func fverify : integer
  1151. strparm LookString
  1152. string DOSChars = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ!@#$%^&()-_{}"
  1153. string char
  1154. integer i, j
  1155.     strlen LookString i
  1156.     if (i > 8) || (i == 0)
  1157.         return 0
  1158.     else
  1159.         i = 0
  1160.         strpeek LookString i j
  1161.         while j != 0
  1162.             strfmt char "%c" j
  1163.             if not strfind DOSChars char
  1164.                 return 0
  1165.             endif
  1166.             i++
  1167.             strpeek LookString i j
  1168.         endwhile
  1169.         return 1
  1170.     endif
  1171. endfunc
  1172. #endif
  1173. #endif
  1174. #endif
  1175.  
  1176.  
  1177. #comment
  1178. *********************************************************************
  1179. * 
  1180. * INLIST()
  1181. * 
  1182. * Called by:
  1183. *  MRUN211H: editpaste()
  1184. *    MRUN211C: addbbs(), exportprompts(), exportmaildoor()
  1185. * 
  1186. * Returns 1 if the first string parameter is contained in
  1187. * the second string, which must be a comma delimited list;
  1188. * otherwise returns 0.
  1189. * 
  1190. *********************************************************************
  1191. #endcomment
  1192.  
  1193. #ifndef MRUN211B
  1194. #ifndef MRUN211DE
  1195. #ifndef MRUN211F
  1196. func inlist: integer
  1197. strparm LookString, ListString
  1198. string Element
  1199. integer i = 0
  1200.     strextract Element ListString "," i
  1201.     while not NULLSTR Element
  1202.         if strcmpi Element LookString
  1203.             return 1
  1204.         endif
  1205.         i++
  1206.         strextract Element ListString "," i
  1207.     endwhile
  1208.     return 0 
  1209. endfunc
  1210. #endif
  1211. #endif
  1212. #endif
  1213.  
  1214.  
  1215. #comment
  1216. *********************************************************************
  1217. * 
  1218. * OPENFILE()
  1219. * 
  1220. * Calls fileexit()
  1221. * 
  1222. * Called by:
  1223. *     MRUN211H:  maketasklist(), makedesc(), clearfiledesc(),
  1224. *                   sortidx(), swapbbs(), taskfilefwd(), fileautorun()
  1225. *     MRUN211D:  main(), purgeoldfiles(), getnewfiles(),
  1226. *                   import(), deldlfile()
  1227. *     MRUN211E:  insertulfile(), killfile(), getulfiles(),
  1228. *                   updateudx()
  1229. *     MRUN211F:  makescriptlist()
  1230. *     MRUN211G:  makequeue(), getdialstring(), senddesc(), putdesc()
  1231. * 
  1232. * Opens a file in the manner specified.  If the file could
  1233. * not be opened successfully, displays an error message and
  1234. * terminates the script.
  1235. * 
  1236. *********************************************************************
  1237. #endcomment
  1238.  
  1239. proc openfile
  1240. intparm FileIndex
  1241. strparm FileNamen
  1242. intparm OpenMethod, OpenType
  1243.     switch OpenMethod
  1244.         case _CREATE
  1245.             switch OpenType
  1246.                 case _TEXT
  1247.                     fopen FileIndex FileNamen CREATE TEXT
  1248.                 endcase
  1249.                 case _NORMAL
  1250.                     fopen FileIndex FileNamen CREATE
  1251.                 endcase
  1252.             endswitch
  1253.         endcase
  1254.         case _READWRITE
  1255.             switch OpenType
  1256.                 case _TEXT
  1257.                     fopen FileIndex FileNamen READWRITE TEXT
  1258.                 endcase
  1259.                 case _NORMAL
  1260.                     fopen FileIndex FileNamen READWRITE
  1261.                 endcase
  1262.             endswitch
  1263.         endcase
  1264.     endswitch
  1265.     if FAILURE
  1266.         errormsg "Unable to open file %s;`r`nscript aborted...." FileNamen
  1267.         fileexit()
  1268.     endif
  1269. endproc
  1270.  
  1271.  
  1272. #comment
  1273. *********************************************************************
  1274. * 
  1275. * CLEARDIR()
  1276. * 
  1277. * Calls makefullname()
  1278. * 
  1279. * Called by:
  1280. *     MRUN211H:  fileexit()
  1281. *     MRUN211A:  initialize()
  1282. *     MRUN211G:  getmail()
  1283. * 
  1284. * Deletes the contents of a directory.
  1285. * 
  1286. *********************************************************************
  1287. #endcomment
  1288.  
  1289. proc cleardir
  1290. strparm DirName
  1291. string DeadFile, DirFiles
  1292.     DirFiles = makefullname(DirName, "*.*")
  1293.     findfirst DirFiles
  1294.     while FOUND
  1295.         DeadFile = makefullname(DirName, $FILENAME)
  1296.         delfile DeadFile
  1297.         findnext
  1298.     endwhile
  1299. endproc
  1300.  
  1301.  
  1302. #comment
  1303. *********************************************************************
  1304. * 
  1305. * CLEARFILEDESC()
  1306. * 
  1307. * Calls openfile()
  1308. * 
  1309. * Called by:
  1310. *     MRUN211D:  main(), deldlfile()
  1311. *     MRUN211E:  main(), insertulfile(), killfile()
  1312. * 
  1313. * Clears the current file description box by creating a
  1314. * new file.
  1315. * 
  1316. *********************************************************************
  1317. #endcomment
  1318.  
  1319. #ifdef MRUN211DE
  1320. proc clearfiledesc
  1321.     openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  1322.     fclose FileDescFile
  1323. endproc
  1324. #endif
  1325.  
  1326.  
  1327. #comment
  1328. *********************************************************************
  1329. * 
  1330. * INSERTITEM()
  1331. * 
  1332. * Calls readitem(), writeitem()
  1333. * 
  1334. * Called by:
  1335. *     MRUN211H:  editpaste()
  1336. *     MRUN211D:  main()
  1337. *     MRUN211E:  insertulfile()
  1338. *     MRUN211F:  addgetmail(), addsendcommand(), adddoscript()
  1339. * 
  1340. * Inserts a new item into the *.MRN file.
  1341. * 
  1342. *********************************************************************
  1343. #endcomment
  1344.  
  1345. proc insertitem
  1346. strparm BBSid
  1347. intparm i
  1348. strparm NovumItem
  1349. string Itemi
  1350. integer j, k
  1351.     j = i - 1
  1352.     Itemi = readitem(BBSid, i)
  1353.     while not NULLSTR Itemi
  1354.         i++
  1355.         Itemi = readitem(BBSid, i)
  1356.     endwhile
  1357.     k = i - 1
  1358.     while k > j
  1359.         Itemi = readitem(BBSid, k)
  1360.         writeitem(BBSid, i, Itemi)
  1361.         i--
  1362.         k--
  1363.     endwhile
  1364.     writeitem(BBSid, i, NovumItem)
  1365. endproc
  1366.  
  1367.  
  1368. #comment
  1369. *********************************************************************
  1370. * 
  1371. * INSERTBBS()
  1372. * 
  1373. * Calls readbbs(), writebbs()
  1374. * 
  1375. * Called by:
  1376. *     MRUN211H:  editpaste()
  1377. *     MRUN211C:  changeuserinfo()
  1378. * 
  1379. * Inserts a new BBS into the *.MRN file.
  1380. * 
  1381. *********************************************************************
  1382. #endcomment
  1383.  
  1384. #ifndef MRUN211B
  1385. #ifndef MRUN211DE
  1386. #ifndef MRUN211F
  1387. #ifndef MRUN211G
  1388. proc insertbbs
  1389. strparm BBSid, NewBBS
  1390. string BBSi
  1391. integer j, k
  1392.     j =  1
  1393.     BBSi = readbbs(j)
  1394.     ;Go to the last BBS
  1395.     while not NULLSTR BBSi
  1396.         j++
  1397.         BBSi = readbbs(j)
  1398.     endwhile
  1399.     k = j - 1
  1400.     ;Count back down, renumbering on the way
  1401.     while not strcmp BBSi BBSid
  1402.         BBSi = readbbs(k)
  1403.         writebbs(j, BBSi)
  1404.         j--
  1405.         k--
  1406.     endwhile
  1407.     writebbs(j, NewBBS)
  1408. endproc
  1409. #endif
  1410. #endif
  1411. #endif
  1412. #endif
  1413.  
  1414.  
  1415. #comment
  1416. *********************************************************************
  1417. * 
  1418. * CHANGEMAILRUN()
  1419. * 
  1420. * Calls filesave(), copymrn(), loadsettings()
  1421. * 
  1422. * Called by: 
  1423. *     MRUN211H:  parsedialog()
  1424. *     MRUN211B:  main()
  1425. * 
  1426. * Saves the last mailrun and loads a new one.
  1427. * 
  1428. *********************************************************************
  1429. #endcomment
  1430.  
  1431. #ifdef MRUN211AB
  1432. proc changemailrun
  1433.     ;Update the last mailrun
  1434.     filesave()
  1435.     ;Get the next mailrun and copy it to the temp directory
  1436.     copymrn()
  1437.     loadsettings(MailRun)
  1438. endproc
  1439. #endif
  1440.  
  1441.  
  1442. #comment
  1443. *********************************************************************
  1444. * 
  1445. * CHECKPENDING()
  1446. * 
  1447. * Calls readitem()
  1448. * 
  1449. * Called by:
  1450. *     MRUN211H:  changestatus()
  1451. *     MRUN211G:  makequeue()
  1452. * 
  1453. * Checks a BBS for currently pending items.  Returns "1" if
  1454. * items are pending, "0" if none are pending.
  1455. * 
  1456. *********************************************************************
  1457. #endcomment
  1458.  
  1459. #ifdef MRUN211AG
  1460. func checkpending : integer
  1461. strparm BBSid
  1462. string Pending, Itemi
  1463. integer i
  1464.     i = 1
  1465.     Itemi = readitem(BBSid, i)
  1466.     while not NULLSTR Itemi
  1467.         strextract Pending Itemi "," 0
  1468.         if strcmpi Pending "1"
  1469.             return 1
  1470.         endif
  1471.         i++
  1472.         Itemi = readitem(BBSid, i)
  1473.     endwhile
  1474.     return 0
  1475. endfunc
  1476. #endif
  1477.  
  1478.  
  1479. #comment
  1480. *********************************************************************
  1481. * 
  1482. * CHECKCHILD()
  1483. * 
  1484. * Called by:
  1485. *     MRUN211A-G:  main()
  1486. * 
  1487. * Halts the script if the current script has not been
  1488. * called by another script.
  1489. * 
  1490. *********************************************************************
  1491. #endcomment
  1492.  
  1493. proc checkchild
  1494.     if not ($CHILD || $CHAINED)
  1495.         errormsg "This script can only be run from MRUN211.WAX."
  1496.         halt
  1497.     endif
  1498. endproc
  1499.  
  1500.  
  1501. #comment
  1502. *********************************************************************
  1503. * 
  1504. * CHECKRUNNING()
  1505. * 
  1506. * Called by:
  1507. *     MRUN211H:  filenewmrun()
  1508. * 
  1509. * Checks whether a mailrun is executing.  Returns 0 and
  1510. * generates a message if running, returns 1 if not.
  1511. * 
  1512. *********************************************************************
  1513. #endcomment
  1514.  
  1515. #ifndef MRUN211G
  1516. func checkrunning : integer
  1517.     if FLAGS & RUNNING
  1518.         usermsg "You cannot create a new mailrun while a mailrun is executing."
  1519.         return 0
  1520.     else
  1521.         return 1
  1522.     endif
  1523. endfunc
  1524. #endif
  1525.  
  1526.  
  1527. #comment
  1528. *********************************************************************
  1529. * 
  1530. * CHECKCHANGED()
  1531. * 
  1532. * Called by:
  1533. *     MRUN211H:  filenewmrun(), cfgmrun(), cfgbbs(), cfgprompts(),
  1534. *                   cfgmaildoor(), defaultsmailrun(), defaultsbbs(),
  1535. *                   defaultsprompts(), defaultsdoor(), addnewbbs(),
  1536. *                   addgetsend(), adddownload(), addupload(), 
  1537. *                   addsendcmd(), addscript(), helpabout()
  1538. *     MRUN211B:  main()
  1539. *     MRUN211C:  changebbsinfo(), changeprompts(), changemaildoor()
  1540. *     MRUN211E:  main()
  1541. * 
  1542. * Checks whether the contents of the current dialog box
  1543. * have changed and generates a warning.  Returns 1 if
  1544. * user elects to proceed or if there has been no change,
  1545. * 0 if user cancels.
  1546. * 
  1547. *********************************************************************
  1548. #endcomment
  1549.  
  1550. func checkchanged : integer
  1551. integer Response
  1552.     if FLAGS & CHANGED
  1553.         sdlgmsgbox "MailRun Message" "Discard Changes?" QUESTION YESNO \
  1554.             Response 2
  1555.         switch Response
  1556.             case 6
  1557.                 FLAGS &= UNCHANGED
  1558.                 return 1
  1559.             endcase
  1560.             case 7
  1561.                 return 0
  1562.             endcase
  1563.         endswitch
  1564.     else
  1565.         return 1
  1566.     endif
  1567. endfunc
  1568.  
  1569.  
  1570. #comment
  1571. *********************************************************************
  1572. * 
  1573. * CHECKFILE()
  1574. * 
  1575. * Called by:
  1576. *     MRUN211A:  initialize()
  1577. *     MRUN211D:  purgeoldfiles(), getnewfiles(), import()
  1578. *     MRUN211E:  main(), getulfiles()
  1579. *     MRUN211G:  senddesc(), putdesc()
  1580. * 
  1581. * Checks for a file's existence.  Returns 1 if the file is
  1582. * found, 0 if not found.
  1583. * 
  1584. *********************************************************************
  1585. #endcomment
  1586.  
  1587. #ifndef MRUN211BC
  1588. #ifndef MRUN211F
  1589. func checkfile : integer
  1590. strparm FileNom
  1591.     if isfile FileNom
  1592.         return 1
  1593.     else
  1594.         return 0
  1595.     endif
  1596. endfunc
  1597. #endif
  1598. #endif
  1599.  
  1600.  
  1601. #comment
  1602. *********************************************************************
  1603. * 
  1604. * CHECKTASK()
  1605. * 
  1606. * Called by:
  1607. *     MRUN211H:  executearchiver(), executeqwkreader(),
  1608. *                   executelogviewer()
  1609. * 
  1610. * Returns 1 if the specified application is already running;
  1611. * otherwise returns 0.
  1612. * 
  1613. *********************************************************************
  1614. #endcomment
  1615.  
  1616. func checktask : integer
  1617. strparm Called
  1618. string AppName
  1619. integer i
  1620.     firsttask i
  1621.     while i
  1622.         taskname i AppName
  1623.         if strfind Called AppName
  1624.             return i
  1625.         endif
  1626.         nexttask i
  1627.     endwhile
  1628.     return 0
  1629. endfunc
  1630.  
  1631.  
  1632. #comment
  1633. *********************************************************************
  1634. * 
  1635. * CHECKNEW()
  1636. * 
  1637. * Called by:
  1638. *     MRUN211H:  cfgbbs(), cfgprompts(), cfgmaildoor(), 
  1639. *                   addgetsend(), adddlfile(), addulfile(),
  1640. *                   addsendcmd(), addscript()
  1641. * 
  1642. * Returns 0 if the current mailrun is empty; else returns 1.
  1643. * 
  1644. *********************************************************************
  1645. #endcomment
  1646.  
  1647. func checknew : integer
  1648.     if NULLSTR TaskItem
  1649.         usermsg "You must add a BBS before selecting this function!"
  1650.         return 0
  1651.     else
  1652.         return 1
  1653.     endif
  1654. endfunc
  1655.  
  1656.  
  1657. #comment
  1658. *********************************************************************
  1659. * 
  1660. * MENUDIM()
  1661. * 
  1662. * Called by:
  1663. *     MRUN211H:  callscript()
  1664. *     MRUN211B-G:  main()
  1665. * 
  1666. * Enables all menu controls, then disables those which
  1667. * cannot be used in the current module.
  1668. * 
  1669. *********************************************************************
  1670. #endcomment
  1671.  
  1672. proc menudim
  1673.     enable MENU 1 32
  1674. #ifndef MRUN211AG
  1675.     disable MENU 3 5
  1676.     disable MENU 8 11
  1677. #endif
  1678. #ifdef MRUN211G
  1679.     disable MENU 1
  1680.     disable MENU 3
  1681.     disable MENU 5 6
  1682. #endif
  1683. endproc
  1684.  
  1685.  
  1686. #comment
  1687. *********************************************************************
  1688. * 
  1689. * SORTIDX()
  1690. * 
  1691. * Calls fieldcompare(), makefullname(), openfile(),
  1692. * interfaceoff(), interfaceon()
  1693. * 
  1694. * Called by:
  1695. *     MRUN211D:  main(), getnewfiles()
  1696. *     MRUN211E:  main(), getulfiles(), updateudx()
  1697. * 
  1698. * Sorts an index file for display in the upload or download
  1699. * dialog box.  This routine uses two temp files to sort the
  1700. * contents of the referenced file.  It is used to sort an
  1701. * index file that has not been previously sorted.  The
  1702. * method used is too slow when only a couple of new items
  1703. * need to be sorted in the file.
  1704. * 
  1705. *********************************************************************
  1706. #endcomment
  1707.  
  1708. #ifdef MRUN211DE
  1709. proc sortidx
  1710. strparm idxName
  1711. intparm SortField
  1712. string temp1, temp2, Line1, Line2, LastLine
  1713. integer Unsorted, Readidx, Writeidx, i, counter
  1714.     SortField -=2
  1715.     if SortField < 0
  1716.         return
  1717.     endif
  1718.     interfaceoff()
  1719.     counter = 0
  1720.     temp1 = makefullname(TempDir, "temp1.tmp")
  1721.     temp2 = makefullname(TempDir, "temp2.tmp")
  1722.     Unsorted = 0
  1723.     Readidx = 1
  1724.     Writeidx = 2
  1725.     openfile(Unsorted, idxName, _READWRITE, _TEXT)
  1726.     fgets Unsorted Line1
  1727.     statmsg "Sorting...     %d" counter
  1728.     if feof Unsorted
  1729.         ;if the index is empty, return
  1730.         fclose Unsorted
  1731.         interfaceon()
  1732.         return
  1733.     else
  1734.         ;otherwise, open temp files and sort
  1735.         openfile(Readidx, temp1, _CREATE, _TEXT)
  1736.         openfile(Writeidx, temp2, _CREATE, _TEXT)
  1737.         ;put the first line into the read file
  1738.         fputs Readidx Line1
  1739.         rewind Readidx
  1740.         ;get the next line of the unsorted file
  1741.         fgets Unsorted Line1
  1742.         counter++
  1743.         statmsg "Sorting...     %d" counter
  1744.         fgets Readidx Line2
  1745.         if feof Unsorted
  1746.             ;prevents a single file from being deleted
  1747.             fputs Writeidx Line2
  1748.         endif
  1749.         while not feof Unsorted
  1750.             while not feof Readidx
  1751.                 if fieldcompare(Line1, Line2, SortField)
  1752.                     exitwhile
  1753.                 endif
  1754.                 fputs Writeidx Line2
  1755.                 fgets Readidx Line2
  1756.             endwhile
  1757.             fputs Writeidx Line1
  1758.             LastLine = Line1
  1759.             fgets Unsorted Line1
  1760.             counter++
  1761.             statmsg "Sorting...     %d" counter
  1762.             if feof Unsorted
  1763.                 while not feof Readidx
  1764.                     fputs Writeidx Line2
  1765.                     fgets Readidx Line2
  1766.                 endwhile
  1767.                 exitwhile
  1768.             elseif !(fieldcompare(Line1, LastLine, SortField))
  1769.                 loopwhile
  1770.             endif
  1771.             while not feof Readidx
  1772.                 fputs Writeidx Line2
  1773.                 fgets Readidx Line2
  1774.             endwhile
  1775.             rewind Readidx
  1776.             rewind Writeidx
  1777.             i = Readidx
  1778.             Readidx = Writeidx
  1779.             Writeidx = i
  1780.             fgets Readidx Line2
  1781.         endwhile
  1782.         fclose Unsorted
  1783.         fclose Readidx
  1784.         fclose Writeidx
  1785.         delfile idxName
  1786.         if Writeidx == 1
  1787.             copyfile temp1 idxName
  1788.         else
  1789.             copyfile temp2 idxName
  1790.         endif
  1791.         delfile temp1
  1792.         delfile temp2
  1793.     endif
  1794.     statmsg ""
  1795.     interfaceon()
  1796. endproc
  1797. #endif
  1798.  
  1799.  
  1800. #comment
  1801. *********************************************************************
  1802. * 
  1803. * FIELDCOMPARE()
  1804. * 
  1805. * Called by:
  1806. *     MRUN211H:  sortidx()
  1807. * 
  1808. * Compares two fields.  Returns 0 if Field1 > Field2,
  1809. * 1 if Field1 <= Field2.
  1810. * 
  1811. *********************************************************************
  1812. #endcomment
  1813.  
  1814. #ifdef MRUN211DE
  1815. func fieldcompare : integer
  1816. strparm Line1, Line2
  1817. intparm FieldType
  1818. string Field1, Field2
  1819. long number1, number2, Date1, Date2
  1820.     strextract Field1 Line1 "`t" FieldType
  1821.     strextract Field2 Line2 "`t" FieldType
  1822.     switch FieldType
  1823.         case ALPHA
  1824.             strcmpi Field1 Field2
  1825.             if $STRCMP >= 0
  1826.                 return 0
  1827.             else
  1828.                 return 1
  1829.             endif
  1830.         endcase
  1831.         case NUMERIC
  1832.             atol Field1 number1
  1833.             atol Field2 number2
  1834.             if number1 >= number2
  1835.                 return 0
  1836.             else
  1837.                 return 1
  1838.             endif
  1839.         endcase
  1840.         case MMDDYY
  1841.             strsltime Field1 "00:00:00" Date1
  1842.             strsltime Field2 "00:00:00" Date2
  1843.             if Date1 >= Date2
  1844.                 return 0
  1845.             else
  1846.                 return 1
  1847.             endif
  1848.         endcase
  1849.     endswitch
  1850. endfunc
  1851. #endif
  1852.  
  1853.  
  1854. #comment
  1855. *********************************************************************
  1856. * 
  1857. * FINDSTRING()
  1858. * 
  1859. * Called by:
  1860. *     MRUN211B:  main()
  1861. *     MRUN211C:  exportprompts()
  1862. *     MRUN211D:  getnewfiles(), import()
  1863. *     MRUN211E:  shortdesc()
  1864. *     MRUN211G:  main(), checkcommandprompt(), getconfprompt(),
  1865. *                   checkmailprompt(), checkdescprompt(), 
  1866. *                   checkbaseset(), getotherprompt(), sendmail(),
  1867. *                   getmail(), checkmail(), ulfile(), checkverifyprompt(),
  1868. *                   senddesc(), dlfile(), sendcommand(), sendscript()
  1869. * 
  1870. * Returns a value of 1 if the second string is contained
  1871. * in the first string; otherwise returns 0.
  1872. * 
  1873. *********************************************************************
  1874. #endcomment
  1875.  
  1876. #ifndef MRUN211A
  1877. #ifndef MRUN211F
  1878. func findstring : integer
  1879. strparm String1, String2
  1880.     if not NULLSTR String2
  1881.         if strfind String1 String2
  1882.             return 1
  1883.         endif
  1884.     endif
  1885.     return 0
  1886. endfunc
  1887. #endif
  1888. #endif
  1889.  
  1890.  
  1891. #comment
  1892. **************************************************************************
  1893. **************************************************************************
  1894. * 
  1895. * The following routines comprise the user interface of MailRun.
  1896. * parsedialog controls the behavior of the main mailrun dialog box,
  1897. * parsemenu() controls the menu and parseobject() controls the
  1898. * toolbar.  The menus and toolbar are defined in MRUN211A in the
  1899. * procedures mrunmenu(), which creates the main menu system, 
  1900. * runmenu(), which creates the alternate menu used when a mailrun
  1901. * is executing, and mrunwin(), which creates the toolbar.
  1902. * 
  1903. **************************************************************************
  1904. **************************************************************************
  1905. #comment
  1906.  
  1907.  
  1908. #comment
  1909. *********************************************************************
  1910. * 
  1911. * INTERFACEON()
  1912. * 
  1913. * Calls parsemenu(), parseobject()
  1914. * 
  1915. * Called by:
  1916. *     MRUN211H:  sortidx(), taskfileend()
  1917. *     MRUN211A:  main()
  1918. *     MRUN211B:  main()
  1919. *     MRUN211C:  changeuserinfo(), changeprompts(), changemaildoor()
  1920. *     MRUN211D:  main(), purgeoldfiles(), getnewfiles(), deldlfile()
  1921. *     MRUN211E:  main(), insertulfile(), getulfiles(), updateudx(),
  1922. *     MRUN211F:  addgetmail(), addsendcommand(), adddoscript()
  1923. *     MRUN211G:  makequeue(), getdialstring(), senddesc(), putdesc()
  1924. * 
  1925. * Activate and deactivate the menu and iconbar.
  1926. * 
  1927. *********************************************************************
  1928. #endcomment
  1929.  
  1930. proc interfaceon
  1931.     when menu call parsemenu
  1932.     when object call parseobject
  1933. endproc
  1934.  
  1935.  
  1936. #comment
  1937. *********************************************************************
  1938. * 
  1939. * INTERFACEOFF()
  1940. * 
  1941. * Called by:
  1942. *     MRUN211H:  sortidx(), taskfilefwd()
  1943. *     MRUN211D:  main(), purgeoldfiles(), getnewfiles(), deldlfile()
  1944. *     MRUN211E:  insertulfile(), geulfiles(), updateudx()
  1945. *     MRUN211G:  makequeue(), getdialstring(), senddesc(), putdesc()
  1946. * 
  1947. * Activate and deactivate the menu and iconbar.
  1948. * 
  1949. *********************************************************************
  1950. #endcomment
  1951.  
  1952. #ifndef MRUN211BC
  1953. #ifndef MRUN211F
  1954. proc interfaceoff
  1955.     clearwhen menu
  1956.     clearwhen object
  1957. endproc
  1958. #endif
  1959. #endif
  1960.  
  1961.  
  1962. #comment
  1963. *********************************************************************
  1964. * 
  1965. * PARSEDIALOG()
  1966. * 
  1967. * Calls changestatus(), changemailrun(), maketasklist(),
  1968. * getfirstitem(), gettaskstring(), swapbbs(), swapitem(),
  1969. * getbbscoord(), makequeue()
  1970. * 
  1971. * Called by
  1972. *  MRUN211A:  main(), executor()
  1973. *  MRUN211G:  main()
  1974. * 
  1975. * Checks for dialog box selection and dispatches the
  1976. * appropriate task.
  1977. * 
  1978. *********************************************************************
  1979. #endcomment
  1980.  
  1981. #ifdef MRUN211AG
  1982. proc parsedialog
  1983. string BBSid, char
  1984. integer dialogstatus, i, j
  1985.     dialogstatus = $DIALOG
  1986.     switch dialogstatus
  1987.         case 10
  1988.             ;User double clicked on an item
  1989.             changestatus()
  1990.             updatedlg 80
  1991.         endcase
  1992.         case 11
  1993.             ;User selected Alt-U to move an item up
  1994.             strextract BBSid TaskItem "`t" 3
  1995.             i = getbbscoord(BBSid)
  1996.             strextract char TaskItem "`t" 4
  1997.             atoi char j
  1998.             if j == 0
  1999.                 ;if the selected TaskItem is a BBS
  2000.                 i--
  2001.                 swapbbs(i)
  2002.             else
  2003.                 ;if the selected TaskItem is an Item
  2004.                 j--
  2005.                 if swapitem(BBSid, j)
  2006.                     TaskItem = gettaskstring(BBSid, j)
  2007.                 endif
  2008.             endif
  2009.             updatedlg 80
  2010.         endcase
  2011.         case 12
  2012.             ;User selected Alt-I to move an item down
  2013.             strextract BBSid TaskItem "`t" 3
  2014.             i = getbbscoord(BBSid)
  2015.             strextract char TaskItem "`t" 4
  2016.             atoi char j
  2017.             if j == 0
  2018.                 ;If the selected TaskItem is a BBS
  2019.                 swapbbs(i)
  2020.             else
  2021.                 ;If the selected TaskItem is an Item
  2022.                 if swapitem(BBSid, j)
  2023.                     j++
  2024.                     TaskItem = gettaskstring(BBSid, j)
  2025.                 endif
  2026.             endif
  2027.             updatedlg 80
  2028.         endcase
  2029. #ifdef MRUN211A
  2030.         case 170
  2031.             ;User changed mailruns with combobox
  2032.             changemailrun()
  2033.             maketasklist()
  2034.             getfirstitem()
  2035.             updatedlg 80
  2036.         endcase
  2037. #endif
  2038.     endswitch
  2039. #ifdef MRUN211G
  2040.     makequeue()
  2041. #endif
  2042. endproc
  2043. #endif
  2044.  
  2045.  
  2046. #comment
  2047. *********************************************************************
  2048. * 
  2049. * SWAPBBS()
  2050. * 
  2051. * Calls readbbs(), writebbs(), openfile(), gettaskstring(),
  2052. * taskfilefwd(), taskfileend()
  2053. * 
  2054. * Called by:
  2055. *  MRUN211H: parsedialog()
  2056. * 
  2057. * Swaps two BBSs in the task list.
  2058. * 
  2059. *********************************************************************
  2060. #endcomment
  2061.  
  2062. #ifdef MRUN211AG
  2063. proc swapbbs
  2064. intparm i
  2065. string FirstBBS, SecondBBS, BBSid, TempTasks, TaskString, temp
  2066. integer j
  2067.     j = i + 1
  2068.     FirstBBS = readbbs(i)
  2069.     SecondBBS = readbbs(j)
  2070.     if NULLSTR FirstBBS
  2071.         return
  2072.     endif
  2073.     if NULLSTR SecondBBS
  2074.         return
  2075.     endif
  2076.     ;Unless this is the last (or first) BBS, swap with the next BBS
  2077.     TaskString = gettaskstring(FirstBBS, 0)
  2078.     taskfilefwd(TaskString)
  2079.     TempTasks = makefullname(TempDir, "tmptasks.tmp")
  2080.     openfile(TempTaskFile, TempTasks, _CREATE, _TEXT)
  2081.     BBSid = FirstBBS
  2082.     while strcmp FirstBBS BBSid
  2083.         fputs TempTaskFile TaskString
  2084.         fgets OldTaskFile TaskString
  2085.         strextract BBSid TaskString "`t" 3
  2086.     endwhile
  2087.     while strcmp SecondBBS BBSid
  2088.         fputs TaskFile TaskString
  2089.         fgets OldTaskFile TaskString
  2090.         strextract BBSid TaskString "`t" 3
  2091.     endwhile
  2092.     temp = TaskString
  2093.     rewind TempTaskFile
  2094.     fgets TempTaskFile TaskString
  2095.     while not feof TempTaskFile
  2096.         fputs TaskFile TaskString
  2097.         fgets TempTaskFile TaskString
  2098.     endwhile
  2099.     fputs TaskFile temp
  2100.     taskfileend()
  2101.     fclose TempTaskFile
  2102.     delfile TempTasks
  2103.     writebbs(i, SecondBBS)
  2104.     writebbs(j, FirstBBS)
  2105. endproc
  2106. #endif
  2107.  
  2108.  
  2109. #comment
  2110. *********************************************************************
  2111. * 
  2112. * SWAPITEM()
  2113. * 
  2114. * Calls readitem(), writeitem(), gettaskstring(), taskfilefwd(),
  2115. * taskfileend()
  2116. * 
  2117. * Called by:
  2118. *  MRUN211H: parsedialog()
  2119. * 
  2120. * Swaps two Items in the task list.
  2121. * 
  2122. *********************************************************************
  2123. #endcomment
  2124.  
  2125. #ifdef MRUN211AG
  2126. func swapitem : integer
  2127. strparm BBSid
  2128. intparm j
  2129. string Itemj, Iteml, TaskString
  2130. integer l
  2131.     if j == 0
  2132.         return 0
  2133.     endif
  2134.     l = j + 1
  2135.     Itemj = readitem(BBSid, j)
  2136.     Iteml = readitem(BBSid, l)
  2137.     if not NULLSTR Iteml
  2138.         ;Unless this is the last Item, swap with the next Item
  2139.         TaskString = gettaskstring(BBSid, j)
  2140.         taskfilefwd(TaskString)
  2141.         writeitem(BBSid, j, Iteml)
  2142.         writeitem(BBSid, l, Itemj)
  2143.         TaskString = gettaskstring(BBSid, j)
  2144.         fputs TaskFile TaskString
  2145.         TaskString = gettaskstring(BBSid, l)
  2146.         fputs TaskFile TaskString
  2147.         fgets OldTaskFile TaskString
  2148.         taskfileend()
  2149.         return 1
  2150.     else
  2151.         return 0
  2152.     endif
  2153. endfunc
  2154. #endif
  2155.  
  2156.  
  2157. #comment
  2158. *********************************************************************
  2159. * 
  2160. * CHANGESTATUS()
  2161. * 
  2162. * Calls readitem(), writeitem(), maketasklist(), gettaskstring(), 
  2163. * checkpending(), taskfilefwd(), taskfileend(), updatecount()
  2164. * 
  2165. * Called by:
  2166. *     MRUN211H:  parsedialog()
  2167. * 
  2168. * Changes the pending/complete permanent/temporary status
  2169. * of the selected item on the task list.  Responds to user
  2170. * double-clicking on the item.
  2171. * 
  2172. *********************************************************************
  2173. #endcomment
  2174.  
  2175. #ifdef MRUN211AG
  2176. proc changestatus
  2177. string Pending, Perm, BBSid, Itemi, char
  2178. integer j
  2179.     strextract BBSid TaskItem "`t" 3
  2180.     strextract char TaskItem "`t" 4
  2181.     atoi char j
  2182.     if j == 0
  2183.         ;If the item is a BBS
  2184.         ;Check for pending items
  2185.         if checkpending(BBSid)
  2186.             ;If at least one item is pending, set all to completed status
  2187.             Pending = "0"
  2188.         else
  2189.             ;If no items are pending, set all to pending status
  2190.             Pending = "1"
  2191.         endif
  2192.         j = 1
  2193.         Itemi = readitem(BBSid, j)
  2194.         ;Update all items
  2195.         while not NULLSTR Itemi
  2196.             strupdt Itemi Pending 0 1
  2197.             writeitem(BBSid, j, Itemi)
  2198.             j++
  2199.             Itemi = readitem(BBSid, j)
  2200.         endwhile
  2201.         maketasklist()
  2202.         TaskItem = gettaskstring(BBSid, 0)
  2203.     else
  2204.         ;If it is not a BBS
  2205.         Itemi = readitem(BBSid, j)
  2206.         strextract Pending Itemi "," 0
  2207.         strextract Perm Itemi "," 1
  2208.         if not strcmpi Pending "1"
  2209.             if strcmpi Pending "0"
  2210.                 ItemC--
  2211.             else
  2212.                 ItemE--
  2213.             endif
  2214.             ItemR++
  2215.             Pending = "1"
  2216.             Perm = "0"
  2217.         else
  2218.             if strcmpi Perm "0"
  2219.                 Perm = "1"
  2220.             else
  2221.                 Pending = "0"
  2222.                 ItemC++
  2223.                 ItemR--
  2224.             endif
  2225.         endif
  2226.         updatecount()
  2227.         strupdt Itemi Pending 0 1
  2228.         strupdt Itemi Perm 2 1
  2229.         taskfilefwd(TaskItem)
  2230.         writeitem(BBSid, j, Itemi)
  2231.         TaskItem = gettaskstring(BBSid, j)
  2232.         fputs TaskFile TaskItem
  2233.         taskfileend()
  2234.     endif
  2235. endproc
  2236. #endif
  2237.  
  2238.  
  2239. #comment
  2240. *********************************************************************
  2241. *
  2242. * TASKFILEFWD()
  2243. *
  2244. * Calls makefullname(), openfile(), interfaceoff()
  2245. *
  2246. * Called by:
  2247. *  MRUN211H:  swapbbs(), swapitem(), changestatus()
  2248. *
  2249. * Opens the Task List file and moves forward to the designated
  2250. * coordinates.
  2251. * 
  2252. *********************************************************************
  2253. #endcomment
  2254.  
  2255. #ifdef MRUN211AG
  2256. proc taskfilefwd
  2257. strparm OldTaskString
  2258. string OldTasks, TaskString
  2259.     interfaceoff()
  2260.     OldTasks = makefullname(TempDir, "oldtasks.tmp")
  2261.     copyfile TaskList OldTasks
  2262.     openfile(OldTaskFile, OldTasks, _READWRITE, _TEXT)
  2263.     openfile(TaskFile, TaskList, _CREATE, _TEXT)
  2264.     fgets OldTaskFile TaskString
  2265.     while not strcmpi OldTaskString TaskString
  2266.         fputs TaskFile TaskString
  2267.         fgets OldTaskFile TaskString
  2268.     endwhile
  2269. endproc
  2270. #endif
  2271.  
  2272.  
  2273. #comment
  2274. *********************************************************************
  2275. *
  2276. * TASKFILEEND()
  2277. *
  2278. * Calls makefullname(), interfaceon()
  2279. *
  2280. * Called by:
  2281. *  MRUN211H:  swapbbs(), swapitem(), changestatus()
  2282. *
  2283. * Reads to the end of the Task List file and closes it.
  2284. * 
  2285. *********************************************************************
  2286. #endcomment
  2287.  
  2288. #ifdef MRUN211AG
  2289. proc taskfileend
  2290. string TaskString, OldTasks
  2291.     fgets OldTaskFile TaskString
  2292.     while not feof OldTaskFile
  2293.         fputs TaskFile TaskString
  2294.         fgets OldTaskFile TaskString
  2295.     endwhile
  2296.     fclose OldTaskFile
  2297.     fclose TaskFile
  2298.     OldTasks = makefullname(TempDir, "oldtasks.tmp")
  2299.     delfile OldTasks
  2300.     interfaceon()
  2301. endproc
  2302. #endif
  2303.  
  2304.  
  2305. #comment
  2306. *********************************************************************
  2307. * 
  2308. * PARSEMENU()
  2309. * 
  2310. * Calls filenewmrun(), filesave(), filesaveas(), filereset(),
  2311. * filedelmrun(), fileautorun(), fileexit(), editcut(), editcopy(), 
  2312. * editpaste(), editdelete(), cfgmrun(), cfgbbs(), cfgprompts(), 
  2313. * cfgmaildoor(), defaultsmailrun(), defaultsbbs(), defaultsprompts(),
  2314. * defaultsdoor(), addnewbbs(), addgetsend(), addupload(),
  2315. * adddownload(), addsendcmd(), addscript(), executemailrun(),
  2316. * executeqwkreader(), executearchiver(), executelogviewer(),
  2317. * helpcontents(), helpcontext(), helpabout()
  2318. * 
  2319. * Called by:
  2320. *     MRUN211H:  interfaceon()
  2321. * 
  2322. * Parses a selection from the MailRun menu.
  2323. * 
  2324. *********************************************************************
  2325. #endcomment
  2326.  
  2327. proc parsemenu
  2328. integer menustatus
  2329.     menustatus = $MENU
  2330.     switch menustatus
  2331. #ifndef MRUN211G
  2332.         case 1
  2333.             ;User selected file.new
  2334.             filenewmrun()
  2335.         endcase
  2336. #endif
  2337.         case 2
  2338.             ;User selected file.save
  2339.             filesave()
  2340.         endcase
  2341. #ifdef MRUN211A
  2342.         case 3
  2343.             ;User selected file.save_as
  2344.             filesaveas()
  2345.         endcase
  2346. #endif
  2347. #ifdef MRUN211AG
  2348.         case 4
  2349.             ;User selected file.reset
  2350.             filereset()
  2351.         endcase
  2352. #endif
  2353. #ifdef MRUN211A
  2354.         case 5
  2355.             ;User selected file.delete_mailrun
  2356.             filedelmrun()
  2357.         endcase
  2358. #endif
  2359. #ifndef MRUN211G
  2360.         case 6
  2361.             ;User selected file.create_autorun
  2362.             fileautorun()
  2363.         endcase
  2364. #endif
  2365.         case 7
  2366.             ;User selected file.exit
  2367.             fileexit()
  2368.         endcase
  2369. #ifdef MRUN211AG
  2370.         case 8
  2371.             ;User selected edit.cut
  2372.             editcut()
  2373.         endcase
  2374.         case 9
  2375.             ;User selected edit.copy
  2376.             editcopy()
  2377.         endcase
  2378.         case 10
  2379.             ;User selected edit.paste
  2380.             editpaste()
  2381.         endcase
  2382.         case 11
  2383.             ;User selected delete_item
  2384.             editdelete()
  2385.         endcase
  2386. #endif
  2387.         case 12
  2388.             ;User selected configure.mailrun_settings
  2389.             cfgmrun()
  2390.         endcase
  2391.         case 13
  2392.             ;User selected configure.bbs_settings
  2393.             cfgbbs()
  2394.         endcase
  2395.         case 14
  2396.             ;User selected configure.bbs_prompts
  2397.             cfgprompts()
  2398.         endcase
  2399.         case 15
  2400.             ;User selected configure.bbs_mail_door
  2401.             cfgmaildoor()
  2402.         endcase
  2403.         case 16
  2404.             ;User selected configure.defaults.mailrun
  2405.             defaultsmailrun()
  2406.         endcase
  2407.         case 17
  2408.             ;User selected configure.defaults.bbs
  2409.             defaultsbbs()
  2410.         endcase
  2411.         case 18
  2412.             ;User selected configure.defaults.prompts
  2413.             defaultsprompts()
  2414.         endcase
  2415.         case 19
  2416.             ;User selected configure.defaults.maildoor
  2417.             defaultsdoor()
  2418.         endcase
  2419.         case 20
  2420.             ;User selected add.new_bbs
  2421.             addnewbbs()
  2422.         endcase
  2423.         case 21
  2424.             ;User selected add.get/send_mail
  2425.             addgetsend()
  2426.         endcase
  2427.         case 22
  2428.             ;User selected add.upload_file
  2429.             addupload()
  2430.         endcase
  2431.         case 23
  2432.             ;User selected add.download_file
  2433.             adddownload()
  2434.         endcase
  2435.         case 24
  2436.             ;User selected add.send_command
  2437.             addsendcmd()
  2438.         endcase
  2439.         case 25
  2440.             ;User selected add.execute_script
  2441.             addscript()
  2442.         endcase
  2443.         case 26
  2444.             ;User selected execute.mailrun
  2445.             executemailrun()
  2446.         endcase
  2447.         case 27
  2448.             ;User selected execute.qwk_reader
  2449.             executeqwkreader()
  2450.         endcase
  2451.         case 28
  2452.             ;User selected execute.archiver
  2453.             executearchiver()
  2454.         endcase
  2455.         case 29
  2456.             ;User selected execute.view_log_file
  2457.             executelogviewer()
  2458.         endcase
  2459.         case 30
  2460.             ;User selected help.contents
  2461.             helpcontents()
  2462.         endcase
  2463.         case 31
  2464.             ;User selected help.current_window
  2465.             helpcontext()
  2466.         endcase
  2467.         case 32
  2468.             ;User selected help.about
  2469.             helpabout()
  2470.         endcase
  2471.     endswitch
  2472. endproc
  2473.  
  2474.  
  2475. #comment
  2476. *********************************************************************
  2477. * 
  2478. * PARSEOBJECT()
  2479. * 
  2480. * Calls executemailrun(), filereset(), filenewmrun(), 
  2481. * cfgbbs(), addnewbbs(), addgetsend(), addupload(),
  2482. * adddownload(), addsendcmd(), addscript(), editdelete(),
  2483. * executelogviewer(), executeqwkreader(), executearchiver(), 
  2484. * fileexit(), helpabout()
  2485. * 
  2486. * Called by:
  2487. *     MRUN211H:  interfaceon()
  2488. * 
  2489. * Parses a selection from the MailRun icon bar.
  2490. * 
  2491. *********************************************************************
  2492. #endcomment
  2493.  
  2494. proc parseobject
  2495. integer objectstatus
  2496.     objectstatus = $OBJECT
  2497.     switch objectstatus
  2498.         case 1
  2499.             ;User selected icon for execute.mailrun
  2500.             executemailrun()
  2501.         endcase
  2502. #ifdef MRUN211AG
  2503.         case 2
  2504.             ;User selected icon for file.reset
  2505.             filereset()
  2506.         endcase
  2507. #endif
  2508. #ifndef MRUN211G
  2509.         case 3
  2510.             ;User selected icon for file.new
  2511.             filenewmrun()
  2512.         endcase
  2513. #endif
  2514.         case 4
  2515.             ;User selected icon for configure.bbs
  2516.             cfgbbs()
  2517.         endcase
  2518.         case 5
  2519.             ;User selected icon for add.new_bbs
  2520.             addnewbbs()
  2521.         endcase
  2522.         case 6
  2523.             ;User selected icon for add.get/send_mail
  2524.             addgetsend()
  2525.         endcase
  2526.         case 7
  2527.             ;User selected icon for add.upload_file
  2528.             addupload()
  2529.         endcase
  2530.         case 8
  2531.             ;User selected icon for add.download_file
  2532.             adddownload()
  2533.         endcase
  2534.         case 9
  2535.             ;User selected icon for add.send_command
  2536.             addsendcmd()
  2537.         endcase
  2538.         case 10
  2539.             ;User selected icon for add.execute_script
  2540.             addscript()
  2541.         endcase
  2542. #ifdef MRUN211AG
  2543.         case 11
  2544.             ;User selected icon for file.delete_item
  2545.             editdelete()
  2546.         endcase
  2547. #endif
  2548.         case 12
  2549.             ;User selected icon for execute.view_log_file
  2550.             executelogviewer()
  2551.         endcase
  2552.         case 13
  2553.             ;User selected icon for execute.qwk_reader
  2554.             executeqwkreader()
  2555.         endcase
  2556.         case 14
  2557.             ;User selected icon for execute.archiver
  2558.             executearchiver()
  2559.         endcase
  2560.         case 15
  2561.             ;User selected icon for file.exit
  2562.             fileexit()
  2563.         endcase
  2564.         case 16
  2565.             ;User selected icon for context sensitive help
  2566.             helpcontext()
  2567.         endcase
  2568.     endswitch
  2569. endproc
  2570.  
  2571.  
  2572. #comment
  2573. **************************************************************************
  2574. **************************************************************************
  2575. * 
  2576. * The following procedures correspond to menu selections
  2577. * and are called from parsemenu() and parseobject().
  2578. * 
  2579. **************************************************************************
  2580. **************************************************************************
  2581. #endcomment
  2582.  
  2583.  
  2584. #comment
  2585. *********************************************************************
  2586. * 
  2587. * FILENEWMRUN()
  2588. * 
  2589. * Calls checkrunning(), checkchanged(), makefullname(),
  2590. * callscript(), MRUN211B\main()
  2591. * 
  2592. * Called by:
  2593. *     MRUN211H:  parsemenu(), parseobject()
  2594. *     
  2595. * Corresponds to File.New_MailRun menu selection.  Creates a 
  2596. * new mailrun.
  2597. *     
  2598. *********************************************************************
  2599. #endcomment
  2600.  
  2601. #ifndef MRUN211G
  2602. proc filenewmrun
  2603. #ifndef MRUN211B
  2604. string changesettings
  2605. #endif
  2606.     if checkrunning() && checkchanged()
  2607.         FLAGS = NEW
  2608. #ifndef MRUN211B
  2609.         changesettings = makefullname(MailRunDir, "MRUN211B")
  2610.         callscript(changesettings)
  2611. #else
  2612.         main()
  2613. #endif
  2614.     endif
  2615. endproc
  2616. #endif
  2617.  
  2618.  
  2619. #comment
  2620. *********************************************************************
  2621. * 
  2622. * FILESAVE()
  2623. * 
  2624. * Calls makefullname()
  2625. * 
  2626. * Called by:
  2627. *     MRUN211H:  parsemenu(), makemrn(), changemailrun(), fileexit()
  2628. *     MRUN211B:  newmailrun()
  2629. * 
  2630. * Corresponds to the File.Save menu selection.  Saves the 
  2631. * current mailrun.
  2632. *     
  2633. *********************************************************************
  2634. #endcomment
  2635.  
  2636. proc filesave
  2637. string LastRun
  2638.     if !(FLAGS & DEFAULTS)
  2639.         findfirst MailRun
  2640.         LastRun = makefullname(MailRunDir, $FILENAME)
  2641.         if not NULLSTR $FILENAME
  2642.             delfile LastRun
  2643.         endif
  2644.         copyfile MailRun LastRun
  2645.         profilewr MailRunIni "MailRun" "MailRun" $FILENAME
  2646.     endif
  2647. endproc
  2648.  
  2649.  
  2650. #comment
  2651. *********************************************************************
  2652. * 
  2653. * FILESAVEAS()
  2654. * 
  2655. * Calls fverify(), makefullname(), copymrn(), makemailrunlist()
  2656. * 
  2657. * Called by:
  2658. *     MRUN211H:  parsemenu()
  2659. * 
  2660. * Corresponds to the File.Save_AS menu selection.  Saves the
  2661. * current mailrun under a new name and makes the new mailrun
  2662. * current.
  2663. * 
  2664. *********************************************************************
  2665. #endcomment
  2666.  
  2667. #ifdef MRUN211A
  2668. proc filesaveas
  2669. string NewRun, temp
  2670. integer Response
  2671.     ;Make sure the entered MailRun ID is the correct length
  2672.     ;and that it doesn't already exist
  2673.     while 1
  2674.         NewRun = ""
  2675.         sdlginput "New MailRun" \
  2676.             "Save the current mailrun as:" NewRun
  2677.         if FAILURE
  2678.             exit
  2679.         endif
  2680.         strlwr NewRun
  2681.         if not fverify(NewRun)
  2682.             usermsg \
  2683.             "A mailrun ID must be a valid DOS file name without the extension."
  2684.             loopwhile
  2685.         endif
  2686.         strfmt temp "%s.mrn" NewRun
  2687.         NewRun = makefullname(MailRunDir, temp)
  2688.         if isfile NewRun
  2689.             sdlgmsgbox "MailRun Message" \
  2690.                 "%s already exists!`r`n`r`nReplace it?" QUESTION YESNO Response 2
  2691.             if Response == 7
  2692.                 ;if user selected "No"
  2693.                 NewRun = ""
  2694.                 loopwhile
  2695.             endif
  2696.         endif
  2697.         exitwhile
  2698.     endwhile
  2699.     delfile NewRun
  2700.     MailRunTrunc = temp
  2701.     copyfile MailRun NewRun
  2702.     copymrn()
  2703.     makemailrunlist()
  2704.     updatedlg 512
  2705. endproc
  2706. #endif
  2707.  
  2708.  
  2709. #comment
  2710. *********************************************************************
  2711. * 
  2712. * FILERESET()
  2713. * 
  2714. * Calls maketasklist(), getfirstitem(), readbbs(), readitem(),
  2715. * writeitem()
  2716. * 
  2717. * Called by:
  2718. *     MRUN211H:  parsemenu(), parseobject(), filereset()
  2719. * 
  2720. * Corresponds to the File.Reset_MailRun menu selection.
  2721. * Resets completed permenant items to pending.  Deletes
  2722. * completed temporary items.
  2723. * 
  2724. *********************************************************************
  2725. #endcomment
  2726.  
  2727. #ifdef MRUN211AG
  2728. proc filereset
  2729. string Pending, Perm, BBSid, Itemi
  2730. integer p1, p2, i, j, k
  2731.     i = 1
  2732.     BBSid = readbbs(i)
  2733.     ;Loop through each BBS
  2734.     while not NULLSTR BBSid
  2735.         j = 1
  2736.         k = 1
  2737.         Itemi = readitem(BBSid, j)
  2738.         ;Loop through each Item
  2739.         while not NULLSTR Itemi
  2740.             ;Clear the old item
  2741.             writeitem(BBSid, j, "")
  2742.             strextract pending Itemi "," 0
  2743.             strextract perm Itemi "," 1
  2744.             atoi pending p1
  2745.             atoi perm p2
  2746.  
  2747.             ;Items that are completed and temporary will not be updated
  2748.             ;The second counter "k" is required to avoid gaps where items
  2749.             ;are deleted.
  2750.  
  2751.             if (p1 != 0) || (p2 != 0)
  2752.                 strupdt Itemi "1" 0 1
  2753.                 writeitem(BBSid, k, Itemi)
  2754.                 k++
  2755.             endif
  2756.             j++
  2757.             Itemi = readitem(BBSid, j)
  2758.         endwhile
  2759.         i++
  2760.         BBSid = readbbs(i)
  2761.     endwhile
  2762.     maketasklist()
  2763.     getfirstitem()
  2764.     updatedlg 80
  2765. endproc
  2766. #endif
  2767.  
  2768.  
  2769. #comment
  2770. *********************************************************************
  2771. * 
  2772. * FILEDELMRUN()
  2773. * 
  2774. * Calls makefullname(), copymrn(), makemailrunlist(),
  2775. * maketasklist(), getfirstitem()
  2776. * 
  2777. * Called by:
  2778. *     MRUN211H:  parsemenu()
  2779. * 
  2780. * Corresponds to the File.Delete_MailRun menu selection.
  2781. * Deletes the current mailrun and makes the next available
  2782. * mailrun current.
  2783. * 
  2784. *********************************************************************
  2785. #endcomment
  2786.  
  2787. #ifdef MRUN211A
  2788. proc filedelmrun
  2789. string LastMRun
  2790.     findfirst MailRun
  2791.     LastMRun = makefullname(MailRunDir, $FILENAME)
  2792.     delfile LastMRun
  2793.     LastMRun = makefullname(MailRunDir, "*.MRN")
  2794.     findfirst LastMRun
  2795.     MailRunTrunc = $FILENAME
  2796.     copymrn()
  2797.     makemailrunlist()
  2798.     maketasklist()
  2799.     getfirstitem()
  2800.     updatedlg -1
  2801. endproc
  2802. #endif
  2803.  
  2804.  
  2805. #comment
  2806. *********************************************************************
  2807. * 
  2808. * FILEAUTORUN()
  2809. * 
  2810. * Calls makefullname(), openfile()
  2811. * 
  2812. * Called by:
  2813. *     MRUN211H:  parsemenu()
  2814. * 
  2815. * Corresponds to the File.Create_AutoRun menu selection.
  2816. * Creates an AutoRun script file.
  2817. * 
  2818. *********************************************************************
  2819. #endcomment
  2820.  
  2821. #ifndef MRUN211G
  2822. proc fileautorun
  2823. string AutoRunFile
  2824.     findfirst MailRun
  2825.     AutoRunFile = makefullname(MailRunDir, $FNAME)
  2826.     strcat AutoRunFile ".WAS"
  2827.     openfile(0, AutoRunFile, _CREATE, _TEXT)
  2828.     fstrfmt 0 ";MailRun autostart script for %s`r`n`r`n" MailRunTrunc
  2829.     fputs 0 "proc main"
  2830.     fputs 0 "string MailRunIni"
  2831.     fputs 0 "`tMailRunIni = $WINPATH"
  2832.     fputs 0 "`taddfilename MailRunIni `"MAILRUN.INI`""
  2833.     fputs 0 "`tprofilewr MailRunIni `"MailRun`" `"AutoRun`" 1"
  2834.     fstrfmt 0 "`tprofilewr MailRunIni `"MailRun`" `"MailRun`" `"%s`"`r`n" \
  2835.         MailRunTrunc
  2836.     fputs 0 "`tchain `"MRUN211`""
  2837.     fputs 0 "endproc"
  2838.     fclose 0
  2839. endproc
  2840. #endif
  2841.  
  2842.  
  2843. #comment
  2844. *********************************************************************
  2845. * 
  2846. * FILEEXIT()
  2847. * 
  2848. * Calls filesave(), cleardir(), makefullname()
  2849. * 
  2850. * Called by:
  2851. *     MRUN211H:  parsemenu(), parseobject()
  2852. *     MRUN211A:  executor()
  2853. *     MRUN211B:  changemrundir()
  2854. *     MRUN211G:  dobbs()
  2855. * 
  2856. * Corresponds to the File.Exit menu selection.  Restores
  2857. * system settings, deletes temporary files, and halts script.
  2858. * 
  2859. *********************************************************************
  2860. #endcomment
  2861.  
  2862. proc fileexit
  2863. string StateCapPath, StateCapFile, StateDnldPath, StateUpldPath
  2864. string CleanupFile
  2865. integer StateAutoDL, StateActionBar, StateMetaKeys
  2866.  
  2867.     ;Update the last mailrun
  2868.     filesave()
  2869.  
  2870.     ;Retrieve the previous system state from the cleanup file
  2871.     cleanupfile = makefullname(TempDir, "CLEANUP.TMP")
  2872.     profilerd CleanupFile "Cleanup" "StateAutoDL" StateAutoDL
  2873.     profilerd CleanupFile "Cleanup" "StateCapPath" StateCapPath
  2874.     profilerd CleanupFile "Cleanup" "StateCapFile" StateCapFile
  2875.     profilerd CleanupFile "Cleanup" "StateDnldPath" StateDnldPath
  2876.     profilerd CleanupFile "Cleanup" "StateUpldPath" StateUpldPath
  2877.     profilerd CleanupFile "Cleanup" "StateActionBar" StateActionBar
  2878.     profilerd CleanupFile "Cleanup" "StateMetaKeys" StateMetaKeys
  2879.  
  2880.     ;Restore the settings
  2881.     capture OFF
  2882.     set capture path StateCapPath
  2883.     set capture file StateCapFile
  2884.     set dnldpath StateDnldPath
  2885.     set upldpath StateUpldPath
  2886.     set aspect rangechk ON
  2887.     if StateAutoDL != 0
  2888.         set autodnld ON
  2889.     endif
  2890.     if StateActionBar != 0
  2891.         actionbar ON
  2892.     endif
  2893.     if StateMetaKeys != 0
  2894.         metakeys ON
  2895.     endif
  2896.  
  2897.     cleardir(TempDir)
  2898.     chdir MailRunDir
  2899.     rmdir TempDir
  2900.     statmsg ""
  2901.     remove USERWIN
  2902. #ifdef MRUN211A
  2903.     if PostRun == 3
  2904.         closepw
  2905.     endif
  2906. #endif
  2907.     halt
  2908. endproc
  2909.  
  2910.  
  2911. #comment
  2912. *********************************************************************
  2913. * 
  2914. * EDITCUT()
  2915. * 
  2916. * Calls editcopy(), editdelete()
  2917. * 
  2918. * Called by:
  2919. *     MRUN211H:  parsemenu()
  2920. * 
  2921. * Corresponds to the Edit.Cut menu selection.  Copies the
  2922. * current item in the Task List to the clipboard and deletes
  2923. * it from the Task List.
  2924. * 
  2925. *********************************************************************
  2926. #endcomment
  2927.  
  2928. #ifdef MRUN211AG
  2929. proc editcut
  2930.     editcopy()
  2931.     editdelete()
  2932. endproc
  2933. #endif
  2934.  
  2935.  
  2936. #comment
  2937. *********************************************************************
  2938. * 
  2939. * EDITCOPY()
  2940. * 
  2941. * Calls makefullname(), loadbbsinfo(), loadprompts(), 
  2942. * loadmaildoor(), writebbsinfo(), writeprompts(),
  2943. * writemaildoor(), readitem()
  2944. * 
  2945. * Called by:
  2946. *     MRUN211H:  parsemenu(), editcut()
  2947. * 
  2948. * Coresponds to the Edit.Copy menu selection.  Copies the 
  2949. * currently selected item in the Task List to the clipboard.
  2950. * If the item is a BBS, all user info and prompts are copied
  2951. * as well.
  2952. * 
  2953. *********************************************************************
  2954. #endcomment
  2955.  
  2956. #ifdef MRUN211AG
  2957. proc editcopy
  2958. string BBSid, Itemi, char, temp
  2959. integer j
  2960.     if NULLSTR TaskItem
  2961.         return
  2962.     endif
  2963.     strextract BBSid TaskItem "`t" 3
  2964.     strextract char TaskItem "`t" 4
  2965.     atoi char j
  2966.     temp = makefullname(TempDir, "TEMP.TMP")
  2967.     ;If the current TaskItem is a BBS...
  2968.     if j == 0
  2969. #ifdef MRUN211G
  2970.         usermsg "Cannot copy/cut a BBS while a mailrun is executing!"
  2971. #else
  2972.         loadbbsinfo(MailRun, BBSid)
  2973.         loadprompts(MailRun, BBSid)
  2974.         loadmaildoor(MailRun, BBSid)
  2975.         profilewr temp "MailRun Data" "BBS" BBSid
  2976.         writebbsinfo(temp, BBSid)
  2977.         writeprompts(temp, BBSid)
  2978.         writemaildoor(temp, BBSid)
  2979.         filetoclip TEXT temp
  2980. #endif
  2981.     else
  2982.         Itemi = readitem(BBSid, j)
  2983.         profilewr temp "MailRun Data" "Item" Itemi
  2984.         filetoclip TEXT temp
  2985.     endif
  2986.     delfile temp
  2987. endproc
  2988. #endif
  2989.  
  2990.  
  2991. #comment
  2992. *********************************************************************
  2993. * 
  2994. * EDITPASTE()
  2995. * 
  2996. * Calls makefullname(), gettaskstring(), inlist(), 
  2997. * insertitem(), makebbslist(), insertbbs(), loadbbsinfo(),
  2998. * loadprompts(), loadmaildoor(), writebbsinfo(), writeprompts(),
  2999. * writemaildoor(), maketasklist()
  3000. * 
  3001. * Called by:
  3002. *     MRUN211H:  parsemenu()
  3003. * 
  3004. * Corresponds to the Edit.Paste menu selection.  Pastes an
  3005. * item from the clipboard into the current mailrun.
  3006. * 
  3007. *********************************************************************
  3008. #endcomment
  3009.  
  3010. #ifdef MRUN211AG
  3011. proc editpaste
  3012. string BBSid, NewBBS, Itemi, char, temp
  3013. integer j
  3014.     strextract BBSid TaskItem "`t" 3
  3015.     strextract char TaskItem "`t" 4
  3016.     atoi char j
  3017.     temp = makefullname(TempDir, "TEMP.TMP")
  3018.     cliptofile TEXT temp
  3019.     profilerd temp "MailRun Data" "Item" Itemi
  3020.     profilerd temp "MailRun Data" "BBS" NewBBS
  3021.     if not NULLSTR Itemi
  3022.         ;if the clipboard contains an item...
  3023.         if NULLSTR TaskItem
  3024.             usermsg "You must add a BBS first!"
  3025.             return
  3026.         endif
  3027.         insertitem(BBSid, j, Itemi)
  3028.         TaskItem = gettaskstring(BBSid, j)
  3029.     elseif not NULLSTR NewBBS
  3030.         ;if the clipboard contains a BBS...
  3031. #ifdef MRUN211G
  3032.         usermsg "Cannot paste a BBS while a mailrun is executing!"
  3033. #else
  3034.         makebbslist()
  3035.         if inlist(NewBBS, BBSList) 
  3036.             errormsg "That BBS is already in the MailRun!"
  3037.             return
  3038.         endif
  3039.         if not NULLSTR BBSList
  3040.             insertbbs(BBSid, NewBBS)
  3041.         else
  3042.             profilewr MailRun "MailRun" "BBS_1" NewBBS
  3043.         endif
  3044.         loadbbsinfo(temp, NewBBS)
  3045.         loadprompts(temp, NewBBS)
  3046.         loadmaildoor(temp, NewBBS)
  3047.         writebbsinfo(MailRun, NewBBS)
  3048.         writeprompts(MailRun, NewBBS)
  3049.         writemaildoor(MailRun, NewBBS)
  3050.         TaskItem = gettaskstring(NewBBS, 0)
  3051. #endif
  3052.     else
  3053.         usermsg "Nothing to paste!"
  3054.         return
  3055.     endif
  3056.     maketasklist()
  3057.     updatedlg 80
  3058. endproc
  3059. #endif
  3060.  
  3061.  
  3062. #comment
  3063. *********************************************************************
  3064. * 
  3065. * EDITDELETE()
  3066. * 
  3067. * Calls readbbs(), readitem(), writebbs(), writeitem(), 
  3068. * maketasklist(), makebbslist(), gettaskstring(), getbbscoord()
  3069. * 
  3070. * Called by:
  3071. *     MRUN211H:  parsemenu(), parseobject(), editcut()
  3072. *     MRUN211A:  parsekeystate()
  3073. * 
  3074. * Corresponds to the Edit.Delete menu selection.  Deletes
  3075. * the currently selected item in the Task List.
  3076. * 
  3077. *********************************************************************
  3078. #endcomment
  3079.  
  3080. #ifdef MRUN211AG
  3081. proc editdelete
  3082. string BBSid, char, Itemi
  3083. integer i, j, k, l
  3084.     strextract BBSid TaskItem "`t" 3
  3085.     i = getbbscoord(BBSid)
  3086.     strextract char TaskItem "`t" 4
  3087.     atoi char j
  3088.     if j == 0
  3089.         ;If the current TaskItem is a BBS...
  3090.         l = i
  3091.         k = l + 1
  3092.         BBSid = readbbs(k)
  3093.  
  3094.         ;Decrement the BBS coordinate of each BBS after the one selected
  3095.  
  3096.         while not NULLSTR BBSid
  3097.             writebbs(l, BBSid)
  3098.             l++
  3099.             k++
  3100.             BBSid = readbbs(k)
  3101.         endwhile
  3102.         writebbs(l, "")
  3103.         ;Update the task list
  3104.         maketasklist()
  3105.  
  3106.         ;Reset the TaskItem.  If the selected BBS was the last one
  3107.         ;in the list, set TaskItem to the previous BBS; otherwise,
  3108.         ;set it to the next BBS
  3109.  
  3110.         BBSid = readbbs(i)
  3111.         if NULLSTR BBSid
  3112.             i--
  3113.             BBSid = readbbs(i)
  3114.             if NULLSTR BBSid
  3115.                 TaskItem = ""
  3116.             else
  3117.                 TaskItem = gettaskstring(BBSid, 0)
  3118.             endif
  3119.         else
  3120.             TaskItem = gettaskstring(BBSid, 0)
  3121.         endif
  3122.  
  3123.     else
  3124.         ;If the current TaskItem is an Item
  3125.         l = j
  3126.         k = l + 1
  3127.  
  3128.         ;Decrement the Item coordinate of each item after the one selected
  3129.  
  3130.         Itemi = readitem(BBSid, k)
  3131.         while not NULLSTR Itemi
  3132.             writeitem(BBSid, l, Itemi)
  3133.             l++
  3134.             k++
  3135.             Itemi = readitem(BBSid, k)
  3136.         endwhile
  3137.         writeitem(BBSid, l, "")
  3138.         ;Update the task list
  3139.         maketasklist()
  3140.  
  3141.         ;Reset the TaskItem to the next Item for that BBS.  If the selected
  3142.         ;Item was the last one for that BBS, set TaskItem to the previous
  3143.         ;Item.  If it was the only item for that BBS, set it to the BBS name.
  3144.  
  3145.         Itemi = readitem(BBSid, j)
  3146.         if not NULLSTR Itemi
  3147.             ;If it wasn't the last item...
  3148.             TaskItem = gettaskstring(BBSid, j)
  3149.         elseif j == 1
  3150.             ;If it was the only item...
  3151.             TaskItem = gettaskstring(BBSid, 0)
  3152.         else
  3153.             ;If it was the last of multiple items...
  3154.             j--
  3155.             TaskItem = gettaskstring(BBSid, j)
  3156.         endif
  3157.     endif
  3158.     updatedlg 80
  3159. endproc
  3160. #endif
  3161.  
  3162.  
  3163. #comment
  3164. *********************************************************************
  3165. * 
  3166. * CFGMRUN()
  3167. * 
  3168. * Calls checkchanged(), configmrun()
  3169. * 
  3170. * Called by:
  3171. *     MRUN211H:  parsemenu()
  3172. * 
  3173. * Corresponds to the Configure.MailRun_Settings menu selection.
  3174. * 
  3175. *********************************************************************
  3176. #endcomment
  3177.  
  3178. proc cfgmrun
  3179.     if checkchanged()
  3180.         ;reset all flags except RUNNING
  3181.         FLAGS &= RUNNING
  3182.         configmrun()
  3183.     endif
  3184. endproc
  3185.  
  3186.  
  3187. #comment
  3188. *********************************************************************
  3189. * 
  3190. * DEFAULTSMAILRUN()
  3191. * 
  3192. * Calls checkchanged(), configmrun()
  3193. * 
  3194. * Called by:
  3195. *     MRUN211H:  parsemenu()
  3196. * 
  3197. * Corresponds to the Configure.Defaults.MailRun menu selection.
  3198. *     
  3199. *********************************************************************
  3200. #endcomment
  3201.  
  3202. proc defaultsmailrun
  3203. #ifdef MRUN211B
  3204.     if FLAGS & DEFAULTS
  3205.         return
  3206.     endif
  3207. #endif
  3208.     if checkchanged()
  3209.         ;reset all flags but RUNNING and set the DEFAULTS flag
  3210.         FLAGS &= RUNNING
  3211.         FLAGS |= DEFAULTS
  3212.         configmrun()
  3213.     endif
  3214. endproc
  3215.  
  3216.  
  3217. #comment
  3218. *********************************************************************
  3219. * 
  3220. * CONFIGMRUN()
  3221. * 
  3222. * Calls MRUN211B\main(), makefullname(), callscript()
  3223. * 
  3224. * Called by:
  3225. *     MRUN211H:  cfgmrun(), defaultsmailrun()
  3226. * 
  3227. * Calls the changesettings script module.
  3228. *     
  3229. *********************************************************************
  3230. #endcomment
  3231.  
  3232. proc configmrun
  3233. #ifdef MRUN211B
  3234.         main()
  3235. #else
  3236. string changesettings
  3237.         changesettings = makefullname(MailRunDir, "MRUN211B")
  3238.         callscript(changesettings)
  3239. #endif
  3240. endproc
  3241.  
  3242.  
  3243. #comment
  3244. *********************************************************************
  3245. * 
  3246. * CFGBBS()
  3247. * 
  3248. * Calls checkchanged(), checknew(), configbbs()
  3249. * 
  3250. * Called by:
  3251. *     MRUN211H:  parsemenu(), parseobject()
  3252. *     MRUN211C:  changeprompts(), changemaildoor()
  3253. * 
  3254. * Corresponds to the Configure.BBS_Settings menu selection.
  3255. * 
  3256. *********************************************************************
  3257. #endcomment
  3258.  
  3259. proc cfgbbs
  3260.     if checkchanged() && checknew()
  3261.         FLAGS &= RUNNING
  3262.         configbbs()
  3263.     endif
  3264. endproc
  3265.  
  3266.  
  3267. #comment
  3268. *********************************************************************
  3269. * 
  3270. * DEFAULTSBBS()
  3271. * 
  3272. * Calls checkchanged(), configbbs()
  3273. * 
  3274. * Called by:
  3275. *     MRUN211H:  parsemenu()
  3276. *     MRUN211C:  changeprompts(), changemaildoor()
  3277. * 
  3278. * Corresponds to the Configure.Defaults.BBS menu selection.
  3279. * 
  3280. *********************************************************************
  3281. #endcomment
  3282.  
  3283. proc defaultsbbs
  3284.     if checkchanged()
  3285.         FLAGS &= RUNNING
  3286.         FLAGS |= DEFAULTS
  3287.         configbbs()
  3288.     endif
  3289. endproc
  3290.  
  3291.  
  3292. #comment
  3293. *********************************************************************
  3294. * 
  3295. * CONFIGBBS()
  3296. * 
  3297. * Calls makefullname(), callscript(), changeuserinfo()
  3298. * 
  3299. * Called by:
  3300. *     MRUN211H:  cfgbbs(), defaultsbbs()
  3301. * 
  3302. * Calls the changebbs script module for the changeuserinfo()
  3303. * procedure.
  3304. * 
  3305. *********************************************************************
  3306. #endcomment
  3307.  
  3308. proc configbbs
  3309. #ifndef MRUN211C
  3310. string changebbs
  3311.         FLAGS = (FLAGS & CLEARCMD) | USR
  3312.         changebbs = makefullname(MailRunDir, "MRUN211C")
  3313.         callscript(changebbs)
  3314. #else
  3315.         changeuserinfo()
  3316. #endif
  3317. endproc
  3318.  
  3319.  
  3320. #comment
  3321. *********************************************************************
  3322. * 
  3323. * CFGPROMPTS()
  3324. * 
  3325. * Calls checkchanged(), checknew(), configprompts
  3326. * 
  3327. * Called by:
  3328. *     MRUN211H:  parsemenu()
  3329. *     MRUN211C:  changeuserinfo(), changemaildoor()
  3330. * 
  3331. * Corresponds to the Configure.BBS_Prompts menu settings.
  3332. * 
  3333. *********************************************************************
  3334. #endcomment
  3335.  
  3336. proc cfgprompts
  3337.     if checkchanged() && checknew()
  3338.         FLAGS &= RUNNING
  3339.         configprompts()
  3340.     endif
  3341. endproc
  3342.  
  3343.  
  3344. #comment
  3345. *********************************************************************
  3346. * 
  3347. * DEFAULTSPROMPTS()
  3348. * 
  3349. * Calls checkchanged(), configprompts()
  3350. * 
  3351. * Called by:
  3352. *     MRUN211H:  parsemenu()
  3353. *     MRUN211C:  changeuserinfo(), changemaildoor()
  3354. * 
  3355. * Corresponds to the Configure.Defaults.Prompts menu selection.
  3356. * 
  3357. *********************************************************************
  3358. #endcomment
  3359.  
  3360. proc defaultsprompts
  3361.     if checkchanged()
  3362.         FLAGS &= RUNNING
  3363.         FLAGS |= DEFAULTS
  3364.         configprompts()
  3365.     endif
  3366. endproc
  3367.  
  3368.  
  3369. #comment
  3370. *********************************************************************
  3371. * 
  3372. * CONFIGPROMPTS()
  3373. * 
  3374. * Calls makefullname(), callscript(), changeprompts()
  3375. * 
  3376. * Called by:
  3377. *     MRUN211H:  cfgprompts(), defaultsprompts()
  3378. * 
  3379. * Calls the changebbs script module for the changeprompts()
  3380. * procedure.
  3381. * 
  3382. *********************************************************************
  3383. #endcomment
  3384.  
  3385. proc configprompts
  3386. #ifndef MRUN211C
  3387. string changebbs
  3388.     FLAGS = (FLAGS & CLEARCMD) | PRMPT
  3389.     changebbs = makefullname(MailRunDir, "MRUN211C")
  3390.     callscript(changebbs)
  3391. #else
  3392.     changeprompts()
  3393. #endif
  3394. endproc
  3395.  
  3396.  
  3397. #comment
  3398. *********************************************************************
  3399. * 
  3400. * CFGMAILDOOR()
  3401. * 
  3402. * Calls checkchanged(), checknew(), configmaildoor()
  3403. * 
  3404. * Called by:
  3405. *     MRUN211H:  parsemenu()
  3406. *     MRUN211C:  changeuserinfo(), changeprompts()
  3407. * 
  3408. * Corresponds to the Configure.BBS_Mail_Door menu selection.
  3409. * 
  3410. *********************************************************************
  3411. #endcomment
  3412.  
  3413. proc cfgmaildoor
  3414.     if checkchanged() && checknew()
  3415.         FLAGS &= RUNNING
  3416.         configmaildoor()
  3417.     endif
  3418. endproc
  3419.  
  3420.  
  3421. #comment
  3422. *********************************************************************
  3423. * 
  3424. * DEFAULTSDOOR()
  3425. * 
  3426. * Calls checkchanged(), configmaildoor()
  3427. * 
  3428. * Called by:
  3429. *     MRUN211H:  parsemenu()
  3430. *     MRUN211C:  changeuserinfo(), changeprompts()
  3431. * 
  3432. * Corresponds to the Configure.Defaults.Mail_Door menu selection.
  3433. * 
  3434. *********************************************************************
  3435. #endcomment
  3436.  
  3437. proc defaultsdoor
  3438.     if checkchanged()
  3439.         FLAGS &= RUNNING
  3440.         FLAGS |= DEFAULTS
  3441.         configmaildoor()
  3442.     endif
  3443. endproc
  3444.  
  3445.  
  3446. #comment
  3447. *********************************************************************
  3448. * 
  3449. * CONFIGMAILDOOR()
  3450. * 
  3451. * Calls makefullname(), callscript(), changemaildoor()
  3452. * 
  3453. * Called by:
  3454. *     MRUN211H:  cfgmaildoor(), defaultsmaildoor()
  3455. * 
  3456. * Calls the changebbs script module for the changemaildoor()
  3457. * procedure.
  3458. * 
  3459. *********************************************************************
  3460. #endcomment
  3461.  
  3462. proc configmaildoor
  3463. #ifndef MRUN211C
  3464. string changebbs
  3465.     FLAGS = (FLAGS & CLEARCMD) | QMD
  3466.     changebbs = makefullname(MailRunDir, "MRUN211C")
  3467.     callscript(changebbs)
  3468. #else
  3469.     changemaildoor()
  3470. #endif
  3471. endproc
  3472.  
  3473.  
  3474. #comment
  3475. *********************************************************************
  3476. * 
  3477. * ADDNEWBBS()
  3478. * 
  3479. * Calls checkchanged(), makefullname(), callscript()
  3480. * MRUN211C\changeuserinfo()
  3481. * 
  3482. * Called by:
  3483. *     MRUN211H:  parsemenu(), parseobject()
  3484. * 
  3485. * Corresponds to the Add.New_BBS menu selection.  Calls the
  3486. * changebbs module for the changeuserinfo() procedure with 
  3487. * the NEW flag set.
  3488. * 
  3489. *********************************************************************
  3490. #endcomment
  3491.  
  3492. proc addnewbbs
  3493. #ifndef MRUN211C
  3494. string changebbs
  3495. #endif
  3496.     if checkchanged()
  3497.         FLAGS &= RUNNING
  3498.         FLAGS |= NEW
  3499. #ifndef MRUN211C
  3500.         FLAGS = (FLAGS & CLEARCMD) | USR
  3501.         changebbs = makefullname(MailRunDir, "MRUN211C")
  3502.         callscript(changebbs)
  3503. #else
  3504.         changeuserinfo()
  3505. #endif
  3506.     endif
  3507. endproc
  3508.  
  3509.  
  3510. #comment
  3511. *********************************************************************
  3512. * 
  3513. * ADDGETSEND()
  3514. * 
  3515. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3516. * MRUN211F\addgetmail()
  3517. * 
  3518. * Called by:
  3519. *     MRUN211H:  parsemenu(), parseobject()
  3520. * 
  3521. * Corresponds to the Add.Get/Send_Mail menu selection.  Calls
  3522. * the othercmds script module for the addgetmail() procedure.
  3523. * 
  3524. *********************************************************************
  3525. #endcomment
  3526.  
  3527. proc addgetsend
  3528. #ifndef MRUN211F
  3529. string othercmds
  3530. #endif
  3531.     if checkchanged() && checknew()
  3532.         FLAGS &= RUNNING
  3533. #ifndef MRUN211F
  3534.         FLAGS = (FLAGS & CLEARCMD) | AGM
  3535.         othercmds = makefullname(MailRunDir, "MRUN211F")
  3536.         callscript(othercmds)
  3537. #else
  3538.         addgetmail()
  3539. #endif
  3540.     endif
  3541. endproc
  3542.  
  3543.  
  3544. #comment
  3545. *********************************************************************
  3546. * 
  3547. * ADDDOWNLOAD()
  3548. * 
  3549. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3550. * 
  3551. * Called by:
  3552. *     MRUN211H:  parsemenu(), parseobject()
  3553. * 
  3554. * Corresponds to the Add.Download_File menu selection.  Calls
  3555. * the adddlfile script module.
  3556. * 
  3557. *********************************************************************
  3558. #endcomment
  3559.  
  3560. proc adddownload
  3561. #ifndef MRUN211D
  3562. string adddlfile
  3563.     if checkchanged() && checknew()
  3564.         FLAGS &= RUNNING
  3565.         adddlfile = makefullname(MailRunDir, "MRUN211D")
  3566.         callscript(adddlfile)
  3567.     endif
  3568. #endif
  3569. endproc
  3570.  
  3571.  
  3572. #comment
  3573. *********************************************************************
  3574. * 
  3575. * ADDUPLOAD()
  3576. * 
  3577. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3578. * 
  3579. * Called by:
  3580. *     MRUN211H:  parsemenu(), parseobject()
  3581. *     
  3582. * Corresponds to the Add.Upload_File menu selection.  Calls
  3583. * the addulfile script module.
  3584. * 
  3585. *********************************************************************
  3586. #endcomment
  3587.  
  3588. proc addupload
  3589. #ifndef MRUN211E
  3590. string addulfile
  3591.     if checkchanged() && checknew()
  3592.         FLAGS &= RUNNING
  3593.         addulfile = makefullname(MailRunDir, "MRUN211E")
  3594.         callscript(addulfile)
  3595.     endif
  3596. #endif
  3597. endproc
  3598.  
  3599.  
  3600. #comment
  3601. *********************************************************************
  3602. * 
  3603. * ADDSENDCMD()
  3604. * 
  3605. * Calls checkchanged(), checknew(), makefullname(), callscript(),
  3606. * MRUN211F\addsendcommand()
  3607. * 
  3608. * Called by:
  3609. *     MRUN211H:  parsemenu(), parseobject()
  3610. *     
  3611. * Corresponds to the Add.Send_Command menu selection.  Calls
  3612. * the othercmds script module for the addsendcommand() procedure.
  3613. * 
  3614. *********************************************************************
  3615. #endcomment
  3616.  
  3617. proc addsendcmd
  3618. #ifndef MRUN211F
  3619. string othercmds
  3620. #endif
  3621.     if checkchanged() && checknew()
  3622.         FLAGS &= RUNNING
  3623. #ifndef MRUN211F
  3624.         FLAGS = (FLAGS & CLEARCMD) | CMD
  3625.         othercmds = makefullname(MailRunDir, "MRUN211F")
  3626.         callscript(othercmds)
  3627. #else
  3628.         addsendcommand()
  3629. #endif
  3630.     endif
  3631. endproc
  3632.  
  3633.  
  3634. #comment
  3635. *********************************************************************
  3636. * 
  3637. * ADDSCRIPT()
  3638. * 
  3639. * Calls checkchanged(), checknew(), makefullname(), callscript(),
  3640. * MRUN211F\adddoscript()
  3641. * 
  3642. * Called by:
  3643. *     MRUN211H:  parsemenu(), parseobject()
  3644. *     
  3645. * Corresponds to the Add.Execute_Script menu selection.  Calls
  3646. * the othercmds script module for the adddoscript() procedure.
  3647. * 
  3648. *********************************************************************
  3649. #endcomment
  3650.  
  3651. proc addscript
  3652. #ifndef MRUN211F
  3653. string othercmds
  3654. #endif
  3655.     if checkchanged() && checknew()
  3656.         FLAGS &= RUNNING
  3657. #ifndef MRUN211F
  3658.         FLAGS = (FLAGS & CLEARCMD) | SCR
  3659.         othercmds = makefullname(MailRunDir, "MRUN211F")
  3660.         callscript(othercmds)
  3661. #else
  3662.         adddoscript()
  3663. #endif
  3664.     endif
  3665. endproc
  3666.  
  3667.  
  3668. #comment
  3669. *********************************************************************
  3670. * 
  3671. * EXECUTEMAILRUN()
  3672. * 
  3673. * Called by:
  3674. *     MRUN211H:  parsemenu(), parseobject()
  3675. *     
  3676. * Corresponds to the Execute.Execute/Terminate_MailRun menu
  3677. * selection.
  3678. * 
  3679. *********************************************************************
  3680. #endcomment
  3681.  
  3682. proc executemailrun
  3683. #ifdef MRUN211G
  3684.     hangup
  3685.     FLAGS &= IDLE
  3686.     capture OFF
  3687.     exit
  3688. #else
  3689.     if FLAGS & RUNNING
  3690.         FLAGS &= IDLE
  3691.     else
  3692.         FLAGS |= RUNNING
  3693.     endif
  3694. #endif
  3695. endproc
  3696.  
  3697.  
  3698. #comment
  3699. *********************************************************************
  3700. * 
  3701. * EXECUTEARCHIVER()
  3702. * 
  3703. * Calls checktask()
  3704. * 
  3705. * Called by:
  3706. *     MRUN211H:  parsemenu(), parseobject()
  3707. * 
  3708. * Corresponds to the Execute.Archiver menu selection.  Calls
  3709. * the archive utility specified in the MailRun Settings
  3710. * dialog.
  3711. * 
  3712. *********************************************************************
  3713. #endcomment
  3714.  
  3715. proc executearchiver
  3716. integer i
  3717. #ifndef MRUN211AB
  3718. string Archiver
  3719. #endif
  3720.     profilerd MailRun "MailRun" "Archiver" Archiver
  3721.     if not NULLSTR Archiver
  3722.         i = checktask(Archiver)
  3723.         if i
  3724.             activatetask i
  3725.         else
  3726.             run Archiver
  3727.         endif
  3728.         if FAILURE
  3729.             usermsg "Unable to run Archive Utility %s .`r`n\
  3730. The file does not exist or is not in your DOS path." Archiver
  3731.         endif
  3732.     else
  3733.         usermsg "You must specify an Archive Utility in`r`n\
  3734. the MailRun Settings dialog box."
  3735.     endif
  3736. endproc
  3737.  
  3738.  
  3739. #comment
  3740. *********************************************************************
  3741. * 
  3742. * EXECUTEQWKREADER()
  3743. * 
  3744. * Calls checktask()
  3745. * 
  3746. * Called by:
  3747. *     MRUN211H:  parsemenu(), parseobject()
  3748. * 
  3749. * Corresponds to the Execute.QWK_Reader menu selection.  Calls
  3750. * the QWK mail reader specified in the MailRun Settings
  3751. * dialog.
  3752. * 
  3753. *********************************************************************
  3754. #endcomment
  3755.  
  3756. proc executeqwkreader
  3757. integer i
  3758. #ifndef MRUN211AB
  3759. string QWKReader
  3760. #endif
  3761.     profilerd MailRun "MailRun" "QWKReader" QWKReader
  3762.     if not NULLSTR QWKReader
  3763.         i = checktask(QWKReader)
  3764.         if i
  3765.             activatetask i
  3766.         else
  3767.             run QWKReader
  3768.         endif
  3769.         if FAILURE
  3770.             usermsg "Unable to run QWK Mail Reader %s.`r`n\
  3771. The file does not exist or is not in your DOS path." QWKReader
  3772.         endif
  3773.     else
  3774.         usermsg "You must specify a QWK Mail Reader in`r`n\
  3775. the MailRun Settings dialog box."
  3776.     endif
  3777. endproc
  3778.  
  3779.  
  3780. #comment
  3781. *********************************************************************
  3782. * 
  3783. * EXECUTELOGVIEWER()
  3784. * 
  3785. * Calls checktask(), makefullname()
  3786. * 
  3787. * Called by:
  3788. *     MRUN211H:  parsemenu(), parseobject()
  3789. *     
  3790. * Corresponds to the Execute.View_Log_File menu selection.  
  3791. * Calls the file viewer specified in the MailRun Settings
  3792. * dialog and loads the log file for the current mailrun.
  3793. * 
  3794. *********************************************************************
  3795. #endcomment
  3796.  
  3797. proc executelogviewer
  3798. string CapFile, RunLine, WinTitle
  3799. integer i, j
  3800. #ifndef MRUN211AB
  3801. string LogViewer
  3802. #endif
  3803.     profilerd MailRun "MailRun" "LogViewer" LogViewer
  3804.     if not NULLSTR LogViewer
  3805.         if not NULLSTR MailRunTrunc
  3806.             CapFile = makefullname(MailRunDir, MailRunTrunc)
  3807.             strlwr CapFile
  3808.             strreplace CapFile ".mrn" ".cap"
  3809.         else
  3810.             CapFile = ""
  3811.         endif
  3812.         i = checktask(LogViewer)
  3813.         if i
  3814.             taskwin i j
  3815.             getwintext j WinTitle
  3816.             if strfind WinTitle CapFile
  3817.                 activatetask i
  3818.                 return
  3819.             endif
  3820.         endif
  3821.         strfmt RunLine "%s %s" LogViewer CapFile
  3822.         run RunLine
  3823.         if FAILURE
  3824.             usermsg "Unable to run Log File Viewer %s.`r`n\
  3825. The file does not exist or is not in your DOS path." LogViewer
  3826.         endif
  3827.     else
  3828.         usermsg "You must specify a Log File Viewer in`r`n\
  3829. the MailRun Settings dialog box."
  3830.     endif
  3831. endproc
  3832.  
  3833.  
  3834. #comment
  3835. *********************************************************************
  3836. * 
  3837. * HELPCONTENTS()
  3838. * 
  3839. * Called by:
  3840. *     MRUN211H:  parsemenu()
  3841. * 
  3842. * Corresponds to the Help.Contents menu selection.  Calls 
  3843. * the help file and displays the contents page.
  3844. * 
  3845. *********************************************************************
  3846. #endcomment
  3847.  
  3848. proc helpcontents
  3849.     help 1
  3850. endproc
  3851.  
  3852.  
  3853. #comment
  3854. *********************************************************************
  3855. * 
  3856. * HELPCONTEXT()
  3857. * 
  3858. * Called by:
  3859. *     MRUN211H:  parsemenu(), parseobject()
  3860. * 
  3861. * Corresponds to the Help.On_current_window menu selection.
  3862. * Calls the help file and displays the page appropriate for
  3863. * the current dialog box.  HelpPage is a global variable set
  3864. * in each procedure that calls a dialog box.
  3865. * 
  3866. *********************************************************************
  3867. #endcomment
  3868.  
  3869. proc helpcontext
  3870.     help HelpPage
  3871. endproc
  3872.  
  3873.  
  3874. #comment
  3875. *********************************************************************
  3876. * 
  3877. * HELPABOUT()
  3878. * 
  3879. * Calls checkchanged(), makefullname(), callscript(),
  3880. * MRUN211F\showabout()
  3881. * 
  3882. * Called by:
  3883. *     MRUN211H:  parsemenu()
  3884. *     MRUN211A:  main()
  3885. * 
  3886. * Corresponds to the Help.About_MailRun menu selection.  Calls
  3887. * the othercmds script module for the showabout() procedure.
  3888. * 
  3889. *********************************************************************
  3890. #endcomment
  3891.  
  3892. proc helpabout
  3893. #ifndef MRUN211F
  3894. string othercmds
  3895. #endif
  3896.     if checkchanged()
  3897.         FLAGS &= RUNNING
  3898. #ifndef MRUN211F
  3899.         FLAGS = (FLAGS & CLEARCMD) | ABT
  3900.         othercmds = makefullname(MailRunDir, "MRUN211F")
  3901.         callscript(othercmds)
  3902. #else
  3903.         showabout()
  3904. #endif
  3905.     endif
  3906. endproc
  3907.  
  3908.  
  3909. #comment
  3910. *********************************************************************
  3911. * 
  3912. * CALLSCRIPT()
  3913. * 
  3914. * Calls menudim(), makemailrunlist(), makebbslist(),
  3915. * maketasklist(), getfirstitem(), MRUN211AG\mailrunbox(),
  3916. * MRUN211G\makequeue()
  3917. * 
  3918. * Called by:
  3919. *     MRUN211H:  filenewmrun(), configmrun(), configbbs(),
  3920. *                   configprompts(), configmaildoor(), addnewbbs(),
  3921. *                   addgetsend(), adddownload(), addupload(),
  3922. *                   addsendcmd(), addscript(), helpabout()
  3923. * 
  3924. * Executes the specified MailRun script module.
  3925. * 
  3926. *********************************************************************
  3927. #endcomment
  3928.  
  3929. proc callscript
  3930. strparm ScriptTitle
  3931. #ifndef MRUN211AG
  3932.     chain ScriptTitle
  3933. #else
  3934. string LastMRun
  3935.     LastMRun = MailRun
  3936.     execute ScriptTitle
  3937.     menudim()
  3938.     FLAGS &= RUNNING
  3939. #ifdef MRUN211G
  3940.     if !(FLAGS & RUNNING)
  3941.         ;if the mailrun has been terminated from another script module...
  3942.         executemailrun()
  3943.     endif
  3944.     profilerd MailRun "MailRun" "LogRun" LogRun
  3945.     if LogRun
  3946.         profilerd MailRun "MailRun" "AnsiInLog" AnsiInLog
  3947.         if AnsiInLog
  3948.             set capture mode append RAW
  3949.         else
  3950.             set capture mode append VISUAL
  3951.         endif
  3952.         capture ON
  3953.     else
  3954.         capture OFF
  3955.     endif
  3956.     makequeue()
  3957. #else
  3958.     findfirst MailRun
  3959.     MailRunTrunc = $FILENAME
  3960.     makemailrunlist()
  3961.     makebbslist()
  3962.     if not strcmpi LastMRun MailRun
  3963.         getfirstitem()
  3964.     endif
  3965. #endif
  3966.     maketasklist()
  3967.     mailrunbox()
  3968.     statmsg ""
  3969. #endif
  3970. endproc
  3971.  
  3972.  
  3973.  
  3974.